reserve p,p1,p2,p3,q,q1,q2 for Point of TOP-REAL 2,
  i for Nat,
  lambda for Real;

theorem Th73:
  for p1,p2 being Point of TOP-REAL 2,
  P being non empty compact Subset of TOP-REAL 2 st
  P is being_simple_closed_curve & p1 in P & p2 in P & not LE p1,p2,P
  holds LE p2,p1,P
proof
  let p1,p2 be Point of TOP-REAL 2,
  P be non empty compact Subset of TOP-REAL 2;
  assume that
A1: P is being_simple_closed_curve and
A2: p1 in P and
A3: p2 in P and
A4: not LE p1,p2,P;
A5: P=Upper_Arc(P) \/ Lower_Arc(P) by A1,JORDAN6:def 9;
A6: not p1=W-min(P) by A1,A3,A4,JORDAN7:3;
  per cases by A2,A3,A5,XBOOLE_0:def 3;
  suppose
A7: p1 in Upper_Arc(P) & p2 in Upper_Arc(P);
A8: Upper_Arc(P) is_an_arc_of W-min(P),E-max(P) by A1,JORDAN6:def 8;
    set q1=W-min(P),q2=E-max(P);
    set Q= Upper_Arc(P);
    now per cases;
      case
A9:     p1<>p2;
        now per cases by A7,A8,A9,JORDAN5C:14;
          case LE p1,p2,Q,q1,q2 & not LE p2,p1,Q,q1,q2;
            hence contradiction by A4,A7,JORDAN6:def 10;
          end;
          case LE p2,p1,Q,q1,q2 & not LE p1,p2,Q,q1,q2;
            hence thesis by A7,JORDAN6:def 10;
          end;
        end;
        hence thesis;
      end;
      case p1=p2;
        hence thesis by A1,A2,JORDAN6:56;
      end;
    end;
    hence thesis;
  end;
  suppose
A10: p1 in Upper_Arc(P) & p2 in Lower_Arc(P);
    now per cases;
      case p2=W-min(P);
        hence thesis by A1,A2,JORDAN7:3;
      end;
      case p2<>W-min(P);
        hence contradiction by A4,A10,JORDAN6:def 10;
      end;
    end;
    hence thesis;
  end;
  suppose p1 in Lower_Arc(P) & p2 in Upper_Arc(P);
    hence thesis by A6,JORDAN6:def 10;
  end;
  suppose
A11: p1 in Lower_Arc(P) & p2 in Lower_Arc(P);
A12: Lower_Arc(P) is_an_arc_of E-max(P),W-min(P) by A1,JORDAN6:50;
    set q2=W-min(P),q1=E-max(P);
    set Q= Lower_Arc(P);
    now per cases;
      case
A13:    p1<>p2;
        now per cases by A11,A12,A13,JORDAN5C:14;
          case
A14:        LE p1,p2,Q,q1,q2 & not LE p2,p1,Q,q1,q2;
            now per cases;
              case p2=W-min(P);
                hence thesis by A1,A2,JORDAN7:3;
              end;
              case p2<>W-min(P);
                hence contradiction by A4,A11,A14,JORDAN6:def 10;
              end;
            end;
            hence thesis;
          end;
          case LE p2,p1,Q,q1,q2 & not LE p1,p2,Q,q1,q2;
            hence thesis by A6,A11,JORDAN6:def 10;
          end;
        end;
        hence thesis;
      end;
      case p1=p2;
        hence thesis by A1,A2,JORDAN6:56;
      end;
    end;
    hence thesis;
  end;
end;
