reserve x for object, X,Y for set;
reserve C for non empty set;
reserve c for Element of C;
reserve f,f1,f2,f3,g,g1 for complex-valued Function;
reserve r,p for Complex;
reserve r,r1,r2,p for Real;
reserve f,f1,f2 for PartFunc of C,REAL;
reserve f for real-valued Function;

theorem
  f|Y is bounded iff ex r st for c being object st c in Y /\ dom f holds
  |.f.c.|<=r
proof
  thus f|Y is bounded implies
ex r st for c being object st c in Y /\ dom f holds
  |.f.c.|<=r
  proof
    assume
A1: f|Y is bounded;
    then consider r1 such that
A2: for c being object st c in Y /\ dom f holds f.c <= r1 by Th70;
    consider r2 such that
A3: for c being object st c in Y /\ dom f holds r2 <= f.c by A1,Th71;
    take g=|.r1.|+|.r2.|;
A4: r1 <= |.r1.| by ABSVALUE:4;
    let c be object such that
A5: c in Y /\ dom f;
    f.c <= r1 by A2,A5;
    then
A6: f.c <= |.r1.| by A4,XXREAL_0:2;
A7: -|.r2.| <= r2 by ABSVALUE:4;
    r2 <= f.c by A3,A5;
    then
A8: -|.r2.| <= f.c by A7,XXREAL_0:2;
    0 <= |.r1.| by COMPLEX1:46;
    then
A9: -|.r1.|+-|.r2.| <= (0 qua Real) + f.c by A8,XREAL_1:7;
    0 <= |.r2.| by COMPLEX1:46;
    then
A10: f.c + (0 qua Real) <= |.r1.|+|.r2.| by A6,XREAL_1:7;
    -|.r1.|+-|.r2.| = -g;
    hence thesis by A10,A9,ABSVALUE:5;
  end;
  given r such that
A11: for c being object st c in Y /\ dom f holds |.f.c.| <= r;
  now
    let c be object;
    assume c in Y /\ dom f;
    then |.f.c.| <= r by A11;
    then
A12: -r <= -|.f.c.| by XREAL_1:24;
    -|.f.c.| <= f.c by ABSVALUE:4;
    hence -r <= f.c by A12,XXREAL_0:2;
  end;
  then
A13: f|Y is bounded_below by Th71;
  now
    let c be object;
    assume c in Y /\ dom f;
    then
A14: |.f.c.| <= r by A11;
    f.c <= |.f.c.| by ABSVALUE:4;
    hence f.c <= r by A14,XXREAL_0:2;
  end;
  then f|Y is bounded_above by Th70;
  hence thesis by A13;
end;
