reserve i,j,k,l,m,n for Nat,
  D for non empty set,
  f for FinSequence of D;
reserve X for compact Subset of TOP-REAL 2;
reserve r for Real;
reserve f for non trivial FinSequence of TOP-REAL 2;
reserve f for non constant standard special_circular_sequence;
reserve z for clockwise_oriented non constant standard
  special_circular_sequence;

theorem Th73:
  z/.1 = N-min L~z implies (S-max L~z)..z < (S-min L~z)..z
proof
  set i1 = (S-max L~z)..z, i2 = (S-min L~z)..z, j = (N-max L~z)..z;
  assume that
A1: z/.1 = N-min L~z and
A2: i1 >= i2;
A3: z/.1 = z/.len z by FINSEQ_6:def 1;
A4: S-min L~z in rng z by Th41;
  then
A5: i2 in dom z by FINSEQ_4:20;
  then
A6: i2 <= len z by FINSEQ_3:25;
A7: 1 <= i2 by A5,FINSEQ_3:25;
A8: S-max L~z in rng z by Th42;
  then
A9: i1 in dom z by FINSEQ_4:20;
  then
A10: z/.i1 = z.i1 by PARTFUN1:def 6
    .= S-max L~z by A8,FINSEQ_4:19;
A11: i1 <= len z by A9,FINSEQ_3:25;
  (N-min L~z)`2 = N-bound L~z & (S-max L~z)`2 = S-bound L~z by EUCLID:52;
  then N-min L~z <> S-max L~z by TOPREAL5:16;
  then
A12: i1 < len z by A1,A11,A10,A3,XXREAL_0:1;
  then i1 + 1 <= len z by NAT_1:13;
  then len z - i1 >= 1 by XREAL_1:19;
  then len z -' i1 >= 1 by NAT_D:39;
  then
A13: len z -' i1 + 1 >= 1+1 by XREAL_1:6;
A14: N-max L~z in rng z by Th40;
  then
A15: j in dom z by FINSEQ_4:20;
  then
A16: 1 <= j by FINSEQ_3:25;
  then i1 > 1 by A1,Lm5,XXREAL_0:2;
  then reconsider M = mid(z,len z,i1) as S-Sequence_in_R2 by A12,Th37;
A17: z/.j = z.j by A15,PARTFUN1:def 6
    .= N-max L~z by A14,FINSEQ_4:19;
  then
A18: (z/.j)`2 = N-bound L~z by EUCLID:52;
  N-min L~z <> N-max L~z by Th52;
  then
A19: 1 < j by A1,A16,A17,XXREAL_0:1;
A20: len z in dom z by FINSEQ_5:6;
  then
A21: M/.1 = z/.len z by A9,Th8;
  1 <= i1 by A9,FINSEQ_3:25;
  then
A22: len M = len z -' i1 + 1 by A11,FINSEQ_6:187;
  then
A23: M/.len M in L~M by A13,JORDAN3:1;
A24: 1 in dom M by FINSEQ_5:6;
A25: j <= len z by A15,FINSEQ_3:25;
A26: i2 > j by A1,Lm6;
  then reconsider h = mid(z,i2,j) as S-Sequence_in_R2 by A6,A19,Th37;
A27: z/.i2 = z.i2 by A5,PARTFUN1:def 6
    .= S-min L~z by A4,FINSEQ_4:19;
  then h/.1 = S-min L~z by A5,A15,Th8;
  then
A28: (h/.1)`2 = S-bound L~z by EUCLID:52;
  h is_in_the_area_of z & h/.len h = z/.j by A5,A15,Th9,Th21,Th22;
  then
A29: len h >= 2 & h is_a_v.c._for z by A18,A28,TOPREAL1:def 8;
  S-min L~z <> S-max L~z by Th56;
  then i1 > i2 by A2,A27,A10,XXREAL_0:1;
  then
A30: L~h misses L~M by A11,A26,A19,Th49;
A31: M/.len M = S-max L~z by A9,A10,A20,Th9;
  per cases;
  suppose that
A32: NW-corner L~z = N-min L~z & SE-corner L~z = S-max L~z;
A33: M is_in_the_area_of z by A9,A20,Th21,Th22;
    (M/.1)`1 = W-bound L~z & (M/.len M)`1 = E-bound L~z by A1,A3,A31,A21,A32,
EUCLID:52;
    then M is_a_h.c._for z by A33;
    hence contradiction by A29,A30,A22,A13,Th29;
  end;
  suppose that
A34: NW-corner L~z = N-min L~z and
A35: SE-corner L~z <> S-max L~z;
    reconsider g = M^<*SE-corner L~z*> as S-Sequence_in_R2 by A9,A10,A20,A35
,Th64;
A36: len g >= 2 & L~g = L~M \/ LSeg(M/.len M,SE-corner L~z) by SPPOL_2:19
,TOPREAL1:def 8;
    len g = len M + len<*SE-corner L~z*> by FINSEQ_1:22
      .= len M + 1 by FINSEQ_1:39;
    then g/.len g = SE-corner L~z by FINSEQ_4:67;
    then
A37: (g/.len g)`1 = E-bound L~z by EUCLID:52;
    M is_in_the_area_of z & <*SE-corner L~z*> is_in_the_area_of z by A9,A20
,Th21,Th22,Th27;
    then
A38: g is_in_the_area_of z by Th24;
    LSeg(M/.len M,SE-corner L~z) /\ L~h c= LSeg(M/.len M,SE-corner L~z)
    /\ L~z by A7,A6,A16,A25,JORDAN4:35,XBOOLE_1:26;
    then
A39: LSeg(M/.len M,SE-corner L~z) /\ L~h c= {M/.len M} by A31,PSCOMP_1:59;
    g/.1 = M/.1 by A24,FINSEQ_4:68
      .= z/.1 by A9,A3,A20,Th8;
    then (g/.1)`1 = W-bound L~z by A1,A34,EUCLID:52;
    then g is_a_h.c._for z by A38,A37;
    hence contradiction by A29,A30,A23,A36,A39,Th29,ZFMISC_1:125;
  end;
  suppose that
A40: NW-corner L~z <> N-min L~z and
A41: SE-corner L~z = S-max L~z;
    reconsider g = <*NW-corner L~z*>^M as S-Sequence_in_R2 by A1,A9,A3,A20,A40
,Th66;
    len M in dom M & len g = len M + len<*NW-corner L~z*> by FINSEQ_1:22
,FINSEQ_5:6;
    then g/.len g = M/.len M by FINSEQ_4:69
      .= S-max L~z by A9,A10,A20,Th9;
    then
A42: (g/.len g)`1 = E-bound L~z by A41,EUCLID:52;
A43: len g >= 2 & L~g = L~M \/ LSeg(NW-corner L~z,M/.1) by SPPOL_2:20
,TOPREAL1:def 8;
    g/.1 = NW-corner L~z by FINSEQ_5:15;
    then
A44: (g/.1)`1 = W-bound L~z by EUCLID:52;
    LSeg(M/.1,NW-corner L~z) /\ L~h c= LSeg(M/.1,NW-corner L~z) /\ L~z by A7,A6
,A16,A25,JORDAN4:35,XBOOLE_1:26;
    then
A45: LSeg(M/.1,NW-corner L~z) /\ L~h c= {M/.1} by A1,A3,A21,PSCOMP_1:43;
A46: M/.1 in L~M by A22,A13,JORDAN3:1;
    M is_in_the_area_of z & <*NW-corner L~z*> is_in_the_area_of z by A9,A20
,Th21,Th22,Th26;
    then g is_in_the_area_of z by Th24;
    then g is_a_h.c._for z by A44,A42;
    hence contradiction by A29,A30,A43,A45,A46,Th29,ZFMISC_1:125;
  end;
  suppose that
A47: NW-corner L~z <> N-min L~z & SE-corner L~z <> S-max L~z;
    set K = <*NW-corner L~z*>^M;
    reconsider g = K^<*SE-corner L~z*> as S-Sequence_in_R2 by A1,A9,A10,A3,A20
,A47,Lm3;
    1 in dom(<*NW-corner L~z*>^M) by FINSEQ_5:6;
    then g/.1 = (<*NW-corner L~z*>^M)/.1 by FINSEQ_4:68
      .= NW-corner L~z by FINSEQ_5:15;
    then
A48: (g/.1)`1 = W-bound L~z by EUCLID:52;
    len g = len(<*NW-corner L~z*>^M) + len<*SE-corner L~z*> by FINSEQ_1:22
      .= len(<*NW-corner L~z*>^M) + 1 by FINSEQ_1:39;
    then g/.len g = SE-corner L~z by FINSEQ_4:67;
    then
A49: (g/.len g)`1 = E-bound L~z by EUCLID:52;
    M is_in_the_area_of z & <*NW-corner L~z*> is_in_the_area_of z by A9,A20
,Th21,Th22,Th26;
    then
A50: <*NW-corner L~z*>^M is_in_the_area_of z by Th24;
    <*SE-corner L~z*> is_in_the_area_of z by Th27;
    then g is_in_the_area_of z by A50,Th24;
    then
A51: g is_a_h.c._for z by A48,A49;
    len K = len M + len<*NW-corner L~z*> by FINSEQ_1:22;
    then len K >= len M by NAT_1:11;
    then len K >= 2 by A22,A13,XXREAL_0:2;
    then
A52: K/.len K in L~K by JORDAN3:1;
    LSeg(M/.1,NW-corner L~z) /\ L~h c= LSeg(M/.1,NW-corner L~z) /\ L~z by A7,A6
,A16,A25,JORDAN4:35,XBOOLE_1:26;
    then
A53: LSeg(M/.1,NW-corner L~z) /\ L~h c= {M/.1} by A1,A3,A21,PSCOMP_1:43;
    L~K = L~M \/ LSeg(NW-corner L~z,M/.1) & M/.1 in L~M by A22,A13,JORDAN3:1
,SPPOL_2:20;
    then
A54: L~K misses L~h by A30,A53,ZFMISC_1:125;
    len M in dom M & len K = len M + len<*NW-corner L~z*> by FINSEQ_1:22
,FINSEQ_5:6;
    then
A55: K/.len K = M/.len M by FINSEQ_4:69
      .= z/.i1 by A9,A20,Th9
      .= S-max L~z by A8,FINSEQ_5:38;
    LSeg(K/.len K,SE-corner L~z) /\ L~h c= LSeg(K/.len K,SE-corner L~z)
    /\ L~z by A7,A6,A16,A25,JORDAN4:35,XBOOLE_1:26;
    then
A56: LSeg(K/.len K,SE-corner L~z) /\ L~h c= {K/.len K} by A55,PSCOMP_1:59;
    len g >= 2 & L~g = L~K \/ LSeg(K/.len K,SE-corner L~z) by SPPOL_2:19
,TOPREAL1:def 8;
    hence contradiction by A29,A51,A54,A52,A56,Th29,ZFMISC_1:125;
  end;
end;
