reserve i,j,k,l,m,n for Nat,
  D for non empty set,
  f for FinSequence of D;
reserve X for compact Subset of TOP-REAL 2;
reserve r for Real;
reserve f for non trivial FinSequence of TOP-REAL 2;
reserve f for non constant standard special_circular_sequence;
reserve z for clockwise_oriented non constant standard
  special_circular_sequence;

theorem
  z/.1 = N-min L~z & S-min L~z <> W-min L~z implies (S-min L~z)..z < (
  W-min L~z)..z
proof
  set i1 = (E-min L~z)..z, i2 = (W-min L~z)..z, j = (S-min L~z)..z;
  assume that
A1: z/.1 = N-min L~z and
A2: S-min L~z <> W-min L~z & j >= i2;
A3: z/.len z = N-min L~z by A1,FINSEQ_6:def 1;
  N-max L~z in L~z by SPRECT_1:11;
  then (N-max L~z)`1 <= E-bound L~z by PSCOMP_1:24;
  then (N-min L~z)`1 < E-bound L~z by Th51,XXREAL_0:2;
  then
A4: (N-min L~z)`1 < (E-min L~z)`1 by EUCLID:52;
A5: E-min L~z in rng z by Th45;
  then
A6: i1 in dom z by FINSEQ_4:20;
  then
A7: 1 <= i1 by FINSEQ_3:25;
  then
A8: j > 1 by A1,Lm9,XXREAL_0:2;
  z/.i1 = z.i1 by A6,PARTFUN1:def 6
    .= E-min L~z by A5,FINSEQ_4:19;
  then
A9: i1 > 1 by A1,A7,A4,XXREAL_0:1;
  (N-min L~z)`2 = N-bound L~z & (S-min L~z)`2 = S-bound L~z by EUCLID:52;
  then
A10: N-min L~z <> S-min L~z by TOPREAL5:16;
A11: S-min L~z in rng z by Th41;
  then
A12: j in dom z by FINSEQ_4:20;
  then
A13: j <= len z by FINSEQ_3:25;
  z/.j = z.j by A12,PARTFUN1:def 6
    .= S-min L~z by A11,FINSEQ_4:19;
  then j < len z by A3,A13,A10,XXREAL_0:1;
  then reconsider h = mid(z,j,len z) as S-Sequence_in_R2 by A8,Th38;
A14: len z in dom z by FINSEQ_5:6;
  then h/.len h = z/.len z by A12,Th9;
  then
A15: (h/.len h)`2 = N-bound L~z by A3,EUCLID:52;
A16: z/.j = z.j by A12,PARTFUN1:def 6
    .= S-min L~z by A11,FINSEQ_4:19;
  then h/.1 = S-min L~z by A12,A14,Th8;
  then
A17: (h/.1)`2 = S-bound L~z by EUCLID:52;
  h is_in_the_area_of z by A12,A14,Th21,Th22;
  then
A18: h is_a_v.c._for z by A17,A15;
A19: i1 < i2 by A1,Lm11;
A20: W-min L~z in rng z by Th43;
  then
A21: i2 in dom z by FINSEQ_4:20;
  then i2 <= len z by FINSEQ_3:25;
  then reconsider M = mid(z,i2,i1) as S-Sequence_in_R2 by A19,A9,Th37;
  M/.len M = z/.i1 by A6,A21,Th9
    .= E-min L~z by A5,FINSEQ_5:38;
  then
A22: (M/.len M)`1 = E-bound L~z by EUCLID:52;
A23: z/.i2 = z.i2 by A21,PARTFUN1:def 6
    .= W-min L~z by A20,FINSEQ_4:19;
  then M/.1 = W-min L~z by A6,A21,Th8;
  then
A24: (M/.1)`1 = W-bound L~z by EUCLID:52;
  M is_in_the_area_of z by A6,A21,Th21,Th22;
  then
A25: M is_a_h.c._for z by A24,A22;
A26: len h >= 2 & len M >= 2 by TOPREAL1:def 8;
  j > i2 by A2,A23,A16,XXREAL_0:1;
  then L~M misses L~h by A19,A9,A13,Th50;
  hence contradiction by A18,A26,A25,Th29;
end;
