reserve m,n,i,i2,j for Nat,
  r,r1,r2,s,t for Real,
  x,y,z for object;
reserve p,p1,p2,p3,q,q1,q2,q3,q4 for Point of TOP-REAL n;
reserve u for Point of Euclid n;
reserve R for Subset of TOP-REAL n;
reserve P,Q for Subset of TOP-REAL n;

theorem Th59:
  for p for P being Subset of TOP-REAL n st R is connected & R is
open & P = {q: q<>p & q in R & not ex f being Function of I[01],TOP-REAL n st f
  is continuous & rng f c= R & f.0=p & f.1=q} holds P is open
proof
  let p;
  let P be Subset of TOP-REAL n;
  assume that
A1: R is connected & R is open and
A2: P = {q: q<>p & q in R & not ex f being Function of I[01],TOP-REAL n
  st f is continuous & rng f c= R & f.0=p & f.1=q};
A3: the TopStruct of TOP-REAL n = TopSpaceMetr(Euclid n) by EUCLID:def 8;
  then reconsider P9=P as Subset of TopSpaceMetr(Euclid n);
A4: P c= R
  proof
    let x be object;
    assume x in P;
    then
    ex q st q=x & q<>p & q in R & not ex f being Function of I[01],TOP-REAL
    n st f is continuous & rng f c= R & f.0=p & f.1=q by A2;
    hence thesis;
  end;
  now
A5: the TopStruct of TOP-REAL n = TopSpaceMetr Euclid n by EUCLID:def 8;
    then reconsider R9=R as Subset of TopSpaceMetr(Euclid n);
    let u;
    reconsider p2=u as Point of TOP-REAL n by TOPREAL3:8;
    assume
A6: u in P;
    R9 is open by A1,A5,PRE_TOPC:30;
    then consider r be Real such that
A7: r>0 and
A8: Ball(u,r) c= R9 by A4,A6,TOPMETR:15;
    take r;
    thus r>0 by A7;
    reconsider r9=r as Real;
A9: p2 in Ball(u,r9) by A7,TBSP_1:11;
    Ball(u,r) c= P9
    proof
      assume not thesis;
      then consider x being object such that
A10:  x in Ball(u,r) and
A11:  not x in P;
      x in R by A8,A10;
      then reconsider q=x as Point of TOP-REAL n;
      per cases by A2,A8,A10,A11;
      suppose
A12:    q=p;
A13:    now
          assume
A14:      q=p2;
          ex p3 st p3=p2 & p3<>p & p3 in R & not ex f1 being Function of
I[01],TOP-REAL n st f1 is continuous & rng f1 c= R & f1.0=p & f1.1=p3 by A2,A6;
          hence contradiction by A12,A14;
        end;
        u in Ball(u,r9) by A7,TBSP_1:11;
        then
A15:    ex f2 being Function of I[01],TOP-REAL n st f2 is continuous & f2.
        0=q & f2.1=p2 & rng f2 c= Ball(u,r9) by A10,A13,Th56;
        not p2 in P
        proof
          assume p2 in P;
          then ex q4 st q4=p2 & q4<>p & q4 in R & not ex f1 being Function of
I[01],TOP-REAL n st f1 is continuous & rng f1 c= R & f1.0=p & f1.1=q4 by A2;
          hence contradiction by A8,A12,A15,XBOOLE_1:1;
        end;
        hence contradiction by A6;
      end;
      suppose
A16:    ex f1 being Function of I[01],TOP-REAL n st f1 is continuous
        & rng f1 c= R & f1.0=p & f1.1=q;
        not p2 in P
        proof
          assume p2 in P;
          then ex q4 st q4=p2 & q4<>p & q4 in R & not ex f1 being Function of
I[01],TOP-REAL n st f1 is continuous & rng f1 c= R & f1.0=p & f1.1=q4 by A2;
          hence contradiction by A8,A9,A10,A16,Th58;
        end;
        hence contradiction by A6;
      end;
    end;
    hence Ball(u,r) c= P9;
  end;
  then P9 is open by TOPMETR:15;
  hence thesis by A3,PRE_TOPC:30;
end;
