reserve T for non empty Abelian
  add-associative right_zeroed right_complementable RLSStruct,
  X,Y,Z,B,C,B1,B2 for Subset of T,
  x,y,p for Point of T;
reserve t,s,r1 for Real;
reserve n for Element of NAT;
reserve X,Y,B1,B2 for Subset of TOP-REAL n;
reserve x,y for Point of TOP-REAL n;
reserve n for Element of NAT;
reserve X,B for Subset of TOP-REAL n;

theorem
  X is convex implies X! is convex
proof
  assume
A1: X is convex;
  for x,y be Point of TOP-REAL n,r be Real st 0 <= r & r <= 1 & x
  in X! & y in X! holds r*x + (1-r)*y in X!
  proof
    let x,y be Point of TOP-REAL n,r be Real;
    assume that
A2: 0 <= r & r <= 1 and
A3: x in X! and
A4: y in X!;
    consider x2 being Point of TOP-REAL n such that
A5: y=-x2 and
A6: x2 in X by A4;
    consider x1 being Point of TOP-REAL n such that
A7: x=-x1 and
A8: x1 in X by A3;
    r*x1 + (1-r)*x2 in X by A1,A2,A8,A6;
    then -(r*x1 + (1-r)*x2) in X!;
    then -(r*x1) - ((1-r)*x2) in X! by RLVECT_1:30;
    then r*(-x1) + -((1-r)*x2) in X! by RLVECT_1:25;
    hence thesis by A7,A5,RLVECT_1:25;
  end;
  hence thesis;
end;
