reserve n,m for Element of NAT;
reserve r,s for Real;
reserve z for Complex;
reserve CNS,CNS1,CNS2 for ComplexNormSpace;
reserve RNS for RealNormSpace;
reserve X,X1 for set;

theorem
  for f be PartFunc of CNS,RNS st f is total & (for x1,x2 be Point of
  CNS holds f/.(x1+x2) = f/.x1 + f/.x2) & (ex x0 be Point of CNS st f
  is_continuous_in x0) holds f is_continuous_on the carrier of CNS
proof
  let f be PartFunc of CNS,RNS;
  assume that
A1: f is total and
A2: for x1,x2 be Point of CNS holds f/.(x1+x2) = f/.x1 + f/.x2;
A3: dom f = the carrier of CNS by A1,PARTFUN1:def 2;
  given x0 be Point of CNS such that
A4: f is_continuous_in x0;
  f/.x0 + 0.RNS = f/.x0 by RLVECT_1:4
    .= f/.(x0+0.CNS) by RLVECT_1:4
    .= f/.x0+f/.0.CNS by A2;
  then
A5: f/.0.CNS = 0.RNS by RLVECT_1:8;
A6: now
    let x1 be Point of CNS;
    0.RNS = f/.(x1+-x1) by A5,RLVECT_1:5
      .= f/.x1+f/.(-x1) by A2;
    hence -(f/.x1)=f/.(-x1) by RLVECT_1:6;
  end;
A7: now
    let x1,x2 be Point of CNS;
    thus f/.(x1-x2)=f/.(x1+-x2) by RLVECT_1:def 11
      .= f/.x1 + f/.(-x2) by A2
      .= f/.x1 +- f/.x2 by A6
      .= f/.x1 - f/.x2 by RLVECT_1:def 11;
  end;
  now
    let x1 be Point of CNS;
    let r be Real;
    assume that
    x1 in the carrier of CNS and
A8: r>0;
    set y=x1-x0;
    consider s such that
A9: 0<s and
A10: for x1 be Point of CNS st x1 in dom f & ||. x1- x0 .|| <s holds
    ||. f/.x1- f/.x0 .|| <r by A4,A8,Th9;
    take s;
    thus s>0 by A9;
    let x2 be Point of CNS such that
    x2 in the carrier of CNS and
A11: ||. x2-x1 .||<s;
A12: y+x0 =x1-(x0-x0) by RLVECT_1:29
      .=x1- 0.CNS by RLVECT_1:15
      .=x1 by RLVECT_1:13;
    then
A13: ||.x2-y-x0.||=||.x2-x1.|| by RLVECT_1:27;
    ||.f/.x2-f/.x1.|| = ||.f/.x2-(f/.y+f/.x0).|| by A2,A12
      .= ||.f/.x2-f/.y-f/.x0 .|| by RLVECT_1:27
      .= ||.f/.(x2-y)-f/.x0.|| by A7;
    hence ||.f/.x2-f/.x1.||<r by A3,A10,A11,A13;
  end;
  hence thesis by A3,Th45;
end;
