reserve x,y for set,
  i for Nat;
reserve V for non empty CLSStruct,
  u,v,v1,v2,v3 for VECTOR of V,
  A for Subset of V,
  l, l1, l2 for C_Linear_Combination of A,
  x,y,y1,y2 for set,
  a,b for Complex,
  F for FinSequence of the carrier of V,
  f for Function of the carrier of V, COMPLEX;
reserve K,L,L1,L2,L3 for C_Linear_Combination of V;
reserve e,e1,e2 for Element of C_LinComb V;

theorem
  for V being ComplexUnitarySpace-like non empty CUNITSTR, M being
Subset of V, v being VECTOR of V, r being Real st M = {u where u is VECTOR of V
  : Im(u .|. v) <= r } holds M is convex
proof
  let V be ComplexUnitarySpace-like non empty CUNITSTR;
  let M be Subset of V;
  let v be VECTOR of V;
  let r be Real;
  assume
A1: M = {u where u is VECTOR of V : Im(u.|.v) <= r };
  let x,y be VECTOR of V;
  let s be Complex;
  assume that
A2: ex p being Real st s=p & 0 < p & p < 1 and
A3: x in M and
A4: y in M;
A5: ex u2 be VECTOR of V st y = u2 & Im(u2.|.v) <= r by A1,A4;
  consider p being Real such that
A6: s=p and
A7: 0 < p and
A8: p < 1 by A2;
  1-p > 0 by A8,XREAL_1:50;
  then
A9: (1-p)*Im(y.|.v) <= (1-p)*r by A5,XREAL_1:64;
  ex u1 be VECTOR of V st x = u1 & Im(u1.|.v) <= r by A1,A3;
  then p*Im(x.|.v) <= p*r by A7,XREAL_1:64;
  then
A10: p*Im(x.|.v) + (1-p)*Im(y.|.v ) <= p*r + (1-p)*r by A9,XREAL_1:7;
  Im( (s*x+(1r-s)*y).|.v ) = Im( (s*x).|.v+((1r-s)*y).|.v ) by CSSPACE:def 13
    .= Im( s*(x.|.v)+((1r-s)*y).|.v ) by CSSPACE:def 13
    .= Im( s*(x.|.v)+(1r-s)*(y.|.v) ) by CSSPACE:def 13
    .= Im( s*(x.|.v))+Im((1r-s)*(y.|.v)) by COMPLEX1:8
    .= p*Im( x.|.v ) + Im((1r-s)*(y.|.v)) by A6,Th43
    .= p*Im( x.|.v ) + (1-p)*Im( y.|.v ) by A6,Th43;
  hence thesis by A1,A10;
end;
