reserve a,a1,a2,b,c,d for Ordinal,
  n,m,k for Nat,
  x,y,z,t,X,Y,Z for set;
reserve f,g for Function;
reserve A,B,C for array;
reserve O for connected non empty Poset;
reserve R,Q for array of O;
reserve T for non empty array of O;
reserve p,q,r,s for Element of dom T;

theorem Th76:
  for C being 0-based arr_computation of R st R is finite array of O
  holds C is finite
  proof
    let C be 0-based arr_computation of R;
    assume R is finite array of O; then
    reconsider R as finite array of O;
A1: C.(base-C) = R by Def14;
    deffunc F(array of O) = card inversions $1;
    base-C = 0 by Th24; then
A2: F(C.0) is finite by A1;
A3: for a st succ a in dom C & F(C.a) is finite holds F(C.succ a) c< F(C.a)
    proof let a; assume
A4:   succ a in dom C & F(C.a) is finite;
      a in succ a by ORDINAL1:6; then
      a in dom C by A4,ORDINAL1:10; then
      consider R,x,y such that
A5:   [x,y] in inversions R & C.a = R & C.succ a = Swap(R,x,y) by A4,Def14;
      inversions R is finite by A4,A5; then
      F(C.succ a) in F(C.a) by A5,Th73; then
      F(C.succ a) c= F(C.a) & F(C.succ a) <> F(C.a) by ORDINAL1:def 2;
      hence F(C.succ a) c< F(C.a);
    end;
    thus C is finite from A(A2,A3);
  end;
