
theorem TrAng1:
for a,b,c be Real st a<b & b<c holds
TriangularFS (a,b,c). a = 0 &
TriangularFS (a,b,c). b = 1 &
TriangularFS (a,b,c). c = 0
proof
 let a,b,c be Real;
 assume A1: a<b & b<c; then
X1a: b-b < c -b by XREAL_1:9;
 set f1=((AffineMap (0,0)) | (REAL \ ].a,c.[));
 set f2= (AffineMap (1/(b - a),- (a / (b - a))) | [.a,b.]);
 set f3=((AffineMap ((- (1 / (c - b))),(c / (c - b)))) | [.b,c.]);
 P2: dom f2 = [.a,b.] by FUNCT_2:def 1;
 P3: dom f3 = [.b,c.] by FUNCT_2:def 1; then
 P8: not a in dom f3 by XXREAL_1:1,A1;
  P9: a in dom f2 by P2,A1;
FA:  TriangularFS (a,b,c).a = (f1+*f2+*f3).a by FUZNUM_1:def 7,A1
  .= (f1+*f2).a by FUNCT_4:11,P8
  .= f2.a by FUNCT_4:13,P9
  .= (AffineMap (1/(b - a),- (a / (b - a)))).a by FUNCT_1:47,P9
  .= (1/(b - a))*a + (- (a / (b - a))) by FCONT_1:def 4
  .=(a*1)/(b - a) + (- (a / (b - a))) by XCMPLX_1:74
  .=0;
  B0: b in dom f3 by P3,A1;
 FB:  TriangularFS (a,b,c).b = (f1+*f2+*f3).b by FUZNUM_1:def 7,A1
  .= f3.b by FUNCT_4:13,B0
  .= (AffineMap ((- (1 / (c - b))),(c / (c - b)))).b by FUNCT_1:47,B0
  .= (- (1 / (c - b)))*b + c / (c - b) by FCONT_1:def 4
  .= (- b*(1 / (c - b))) + c / (c - b)
  .= - ((b*1) / (c - b)) + c / (c - b) by XCMPLX_1:74
  .= (-b) / (c - b) + c / (c - b) by XCMPLX_1:187
  .= ( - b+c) / (c - b) by XCMPLX_1:62
  .=1 by XCMPLX_1:60,X1a;
  C0: c in dom f3 by P3,A1;
  TriangularFS (a,b,c).c = (f1+*f2+*f3).c by FUZNUM_1:def 7,A1
  .= f3.c by FUNCT_4:13,C0
  .= (AffineMap ((- (1 / (c - b))),(c / (c - b)))).c by FUNCT_1:47,C0
  .= (- (1 / (c - b)))*c + c / (c - b) by FCONT_1:def 4
  .= (- c*(1 / (c - b))) + c / (c - b)
  .= - (c*1) / (c - b) + c / (c - b) by XCMPLX_1:74
  .=0;
 hence thesis by FA,FB;
end;
