reserve x,O for set,
  o for Element of O,
  G,H,I for GroupWithOperators of O,
  A, B for Subset of G,
  N for normal StableSubgroup of G,
  H1,H2,H3 for StableSubgroup of G,
  g1,g2 for Element of G,
  h1,h2 for Element of H1,
  h for Homomorphism of G,H;
reserve E for set,
  A for Action of O,E,
  C for Subset of G,
  N1 for normal StableSubgroup of H1;

theorem Th76:
  H1./.N1 is trivial implies the HGrWOpStr of H1 = the HGrWOpStr of N1
proof
  reconsider N9=N1 as StableSubgroup of G by Th11;
  set H=H1;
  reconsider N=the multMagma of N1 as normal Subgroup of H by Lm6;
  assume
A1: H1./.N1 is trivial;
  Cosets N1 = Cosets N by Def14;
  then consider e be object such that
A2: the carrier of H./.N = {e} by A1;
A3: the carrier of H = union {e} by A2,GROUP_2:137;
A4: now
    assume not the carrier of H c= the carrier of N;
    then (the carrier of H) \ (the carrier of N) <> {} by XBOOLE_1:37;
    then consider x being object such that
A5: x in (the carrier of H) \ (the carrier of N) by XBOOLE_0:def 1;
    reconsider x as Element of H1 by A5;
A6: now
      assume x * N = e;
      then x * N = the carrier of H by A3,ZFMISC_1:25;
      then consider x9 be Element of H such that
A7:   1_H = x * x9 and
A8:   x9 in N by GROUP_2:103;
      x9=x" by A7,GROUP_1:12;
      then x"" in N by A8,GROUP_2:51;
      then x in carr(N) by STRUCT_0:def 5;
      hence contradiction by A5,XBOOLE_0:def 5;
    end;
    x * N in Cosets N by GROUP_6:14;
    hence contradiction by A2,A6,TARSKI:def 1;
  end;
  the carrier of N c= the carrier of H by GROUP_2:def 5;
  then the carrier of N9 = the carrier of H1 by A4,XBOOLE_0:def 10;
  hence thesis by Th75;
end;
