reserve a for Real;
reserve p,q for Point of TOP-REAL 2;

theorem Th76:
  for cn being Real,q being Point of TOP-REAL 2 st -1<cn & q`2>0 &
q`1/|.q.|<cn holds for p being Point of TOP-REAL 2 st p=(cn-FanMorphN).q holds
  p`2>0 & p`1<0
proof
  let cn be Real,q be Point of TOP-REAL 2;
  assume that
A1: -1<cn and
A2: q`2>0 and
A3: q`1/|.q.|<cn;
A4: 1+cn>0 by A1,XREAL_1:148;
  let p be Point of TOP-REAL 2;
  set qz=p;
  assume p=(cn-FanMorphN).q;
  then
  p=|[ |.q.|* ((q`1/|.q.|-cn)/(1+cn)), |.q.|*( sqrt(1-((q`1/|.q.|-cn)/(1+
  cn))^2))]| by A2,A3,Th50;
  then
A5: qz`2= |.q.|*( sqrt(1-((q`1/|.q.|-cn)/(1+cn))^2)) & qz`1= |.q.|* ((q`1/
  |.q.|- cn)/(1+cn)) by EUCLID:52;
A6: |.q.|<>0 by A2,JGRAPH_2:3,TOPRNS_1:24;
  then
A7: (|.q.|)^2>0 by SQUARE_1:12;
A8: (q`1/|.q.|-cn)< 0 by A3,XREAL_1:49;
  then -( q`1/|.q.|-cn)>0 by XREAL_1:58;
  then (-(1+cn))/(1+cn)<(-( q`1/|.q.|-cn))/(1+cn) by A4,XREAL_1:74;
  then
A9: -1<(-( q`1/|.q.|-cn))/(1+cn) by A4,XCMPLX_1:197;
  (|.q.|)^2 =(q`1)^2+(q`2)^2 & 0+(q`1)^2<(q`1)^2+(q`2)^2 by A2,JGRAPH_3:1
,SQUARE_1:12,XREAL_1:8;
  then (q`1)^2/(|.q.|)^2 < (|.q.|)^2/(|.q.|)^2 by A7,XREAL_1:74;
  then (q`1)^2/(|.q.|)^2 < 1 by A7,XCMPLX_1:60;
  then ((q`1)/|.q.|)^2 < 1 by XCMPLX_1:76;
  then -1<q`1/|.q.| by SQUARE_1:52;
  then -1-cn<q`1/|.q.|-cn by XREAL_1:9;
  then --(1+cn)> -(q`1/|.q.|-cn) by XREAL_1:24;
  then (-(q`1/|.q.|-cn))/(1+cn)<1 by A4,XREAL_1:191;
  then ((-(q`1/|.q.|-cn))/(1+cn))^2<1^2 by A9,SQUARE_1:50;
  then 1-((-(q`1/|.q.|-cn))/(1+cn))^2>0 by XREAL_1:50;
  then sqrt(1-((-(q`1/|.q.|-cn))/(1+cn))^2)>0 by SQUARE_1:25;
  then sqrt(1-(-(q`1/|.q.|-cn))^2/(1+cn)^2)> 0 by XCMPLX_1:76;
  then sqrt(1-(q`1/|.q.|-cn)^2/(1+cn)^2)> 0;
  then
A10: sqrt(1-((q`1/|.q.|-cn)/(1+cn))^2)> 0 by XCMPLX_1:76;
  ((q`1/|.q.|-cn)/(1+cn))<0 by A1,A8,XREAL_1:141,148;
  hence thesis by A6,A5,A10,XREAL_1:129,132;
end;
