reserve m,n,i,i2,j for Nat,
  r,r1,r2,s,t for Real,
  x,y,z for object;
reserve p,p1,p2,p3,q,q1,q2,q3,q4 for Point of TOP-REAL n;
reserve u for Point of Euclid n;
reserve R for Subset of TOP-REAL n;
reserve P,Q for Subset of TOP-REAL n;

theorem Th60:
  for P being Subset of TOP-REAL n st R is connected & R is open &
  p in R & P = {q: q=p or ex f being Function of I[01],TOP-REAL n st f is
  continuous & rng f c= R & f.0=p & f.1=q} holds P is open
proof
  let P be Subset of TOP-REAL n;
  assume that
A1: R is connected & R is open and
A2: p in R and
A3: P = {q: q=p or ex f being Function of I[01],TOP-REAL n st f is
  continuous & rng f c= R & f.0=p & f.1=q};
A4: the TopStruct of TOP-REAL n = TopSpaceMetr(Euclid n) by EUCLID:def 8;
  then reconsider P9=P as Subset of TopSpaceMetr(Euclid n);
  reconsider RR=R as Subset of TopSpaceMetr(Euclid n) by A4;
  now
    let u;
    reconsider p2=u as Point of TOP-REAL n by TOPREAL3:8;
    assume u in P9;
    then consider q1 such that
A5: q1=u and
A6: q1=p or ex f being Function of I[01],TOP-REAL n st f is continuous
    & rng f c= R & f.0=p & f.1=q1 by A3;
A7: now
      per cases by A6;
      suppose
        q1=p;
        hence p2 in R by A2,A5;
      end;
      suppose
        q1<>p & ex f being Function of I[01],TOP-REAL n st f is
        continuous & rng f c= R & f.0=p & f.1=q1;
        then consider f2 being Function of I[01],TOP-REAL n such that
        f2 is continuous and
A8:     rng f2 c= R and
        f2.0=p and
A9:     f2.1=q1;
        dom f2=[.0,1.] by BORSUK_1:40,FUNCT_2:def 1;
        then 1 in dom f2 by XXREAL_1:1;
        then u in rng f2 by A5,A9,FUNCT_1:def 3;
        hence p2 in R by A8;
      end;
    end;
    RR is open by A1,A4,PRE_TOPC:30;
    then consider r be Real such that
A10: r>0 and
A11: Ball(u,r) c= R by A7,TOPMETR:15;
    take r;
    thus r>0 by A10;
    reconsider r9=r as Real;
A12: p2 in Ball(u,r9) by A10,TBSP_1:11;
    thus Ball(u,r) c= P
    proof
      let x be object;
      assume
A13:  x in Ball(u,r);
      then reconsider q=x as Point of TOP-REAL n by A11,TARSKI:def 3;
      per cases;
      suppose
        q=p;
        hence thesis by A3;
      end;
      suppose
A14:    q<>p;
A15:    now
          assume q1=p;
          then p in Ball(u,r9) by A5,A10,TBSP_1:11;
          then consider f2 being Function of I[01],TOP-REAL n such that
A16:      f2 is continuous & f2.0=p & f2.1=q and
A17:      rng f2 c= Ball(u,r9) by A13,A14,Th56;
          rng f2 c= R by A11,A17;
          hence thesis by A3,A16;
        end;
        now
          assume q1<>p;
          then ex f being Function of I[01],TOP-REAL n st f is continuous &
          rng f c= R & f.0=p & f.1=q by A5,A6,A11,A12,A13,Th58;
          hence thesis by A3;
        end;
        hence thesis by A15;
      end;
    end;
  end;
  then P9 is open by TOPMETR:15;
  hence thesis by A4,PRE_TOPC:30;
end;
