reserve T for non empty Abelian
  add-associative right_zeroed right_complementable RLSStruct,
  X,Y,Z,B,C,B1,B2 for Subset of T,
  x,y,p for Point of T;
reserve t,s,r1 for Real;
reserve n for Element of NAT;
reserve X,Y,B1,B2 for Subset of TOP-REAL n;
reserve x,y for Point of TOP-REAL n;
reserve n for Element of NAT;
reserve X,B for Subset of TOP-REAL n;

theorem Th76:
  X is convex & B is convex implies X (+) B is convex & X (-) B is convex
proof
  assume that
A1: X is convex and
A2: B is convex;
  for x,y be Point of TOP-REAL n,r be Real st 0 <= r & r <= 1 & x
  in X (+) B & y in X (+) B holds r*x + (1-r)*y in X (+) B
  proof
    let x,y be Point of TOP-REAL n,r be Real;
    assume that
A3: 0 <= r & r <= 1 and
A4: x in X (+) B and
A5: y in X (+) B;
    consider x2,b2 being Point of TOP-REAL n such that
A6: y=x2+b2 and
A7: x2 in X & b2 in B by A5;
    consider x1,b1 being Point of TOP-REAL n such that
A8: x=x1+b1 and
A9: x1 in X & b1 in B by A4;
    r*x1 + (1-r)*x2 in X & r*b1 + (1-r)*b2 in B by A1,A2,A3,A9,A7;
    then
    (r*x1 + (1-r)*x2)+(r*b1 + (1-r)*b2) in {x3+b3 where x3,b3 is Point of
    TOP-REAL n:x3 in X&b3 in B};
    then (r*x1 + (1-r)*x2)+r*b1 + (1-r)*b2 in X (+) B by RLVECT_1:def 3;
    then r*x1 + r*b1+(1-r)*x2 + (1-r)*b2 in X (+) B by RLVECT_1:def 3;
    then (r*x1 + r*b1)+((1-r)*x2 + (1-r)*b2) in X (+) B by RLVECT_1:def 3;
    then r*(x1 + b1)+((1-r)*x2 + (1-r)*b2) in X (+) B by RLVECT_1:def 5;
    hence thesis by A8,A6,RLVECT_1:def 5;
  end;
  hence X (+) B is convex;
  for x,y be Point of TOP-REAL n,r be Real st 0 <= r & r <= 1 & x
  in X (-) B & y in X (-) B holds r*x + (1-r)*y in X (-) B
  proof
    let x,y be Point of TOP-REAL n,r be Real;
    assume that
A10: 0 <= r & r <= 1 and
A11: x in X (-) B & y in X (-) B;
A12: (ex x1 being Point of TOP-REAL n st x=x1 & B+x1 c= X )& ex y1 being
    Point of TOP-REAL n st y=y1 & B+y1 c= X by A11;
    B+(r*x + (1-r)*y) c= X
    proof
      let b1 be object;
      assume b1 in B+(r*x + (1-r)*y);
      then consider b being Point of TOP-REAL n such that
A13:  b1=b+(r*x + (1-r)*y) and
A14:  b in B;
      b+x in B+x & b+y in {b2+y where b2 is Point of TOP-REAL n:b2 in B}
      by A14;
      then r*(b+x) + (1-r)*(b+y) in X by A1,A10,A12;
      then r*b+r*x + (1-r)*(b+y) in X by RLVECT_1:def 5;
      then r*b+r*x + ((1-r)*b+(1-r)*y) in X by RLVECT_1:def 5;
      then r*b+r*x + (1-r)*b+(1-r)*y in X by RLVECT_1:def 3;
      then r*b+r*x + (1*b-r*b)+(1-r)*y in X by RLVECT_1:35;
      then r*b+r*x + 1*b-r*b+(1-r)*y in X by RLVECT_1:def 3;
      then r*x+1*b + r*b-r*b+(1-r)*y in X by RLVECT_1:def 3;
      then r*x+1*b +(1-r)*y in X by RLVECT_4:1;
      then 1*b +(r*x+(1-r)*y) in X by RLVECT_1:def 3;
      hence thesis by A13,RLVECT_1:def 8;
    end;
    hence thesis;
  end;
  hence thesis;
end;
