reserve i,j,k,l,m,n for Nat,
  D for non empty set,
  f for FinSequence of D;
reserve X for compact Subset of TOP-REAL 2;
reserve r for Real;
reserve f for non trivial FinSequence of TOP-REAL 2;
reserve f for non constant standard special_circular_sequence;
reserve z for clockwise_oriented non constant standard
  special_circular_sequence;

theorem
  z/.1 = N-min L~z implies (W-min L~z)..z < len z
proof
  assume
A1: z/.1 = N-min L~z;
A2: W-max L~z in rng z by Th44;
A3: W-min L~z in rng z by Th43;
  per cases;
  suppose
    N-min L~z = W-max L~z;
    then
A4: z/.len z = W-max L~z by A1,FINSEQ_6:def 1;
A5: (W-min L~z)..z in dom z by A3,FINSEQ_4:20;
    then
A6: (W-min L~z)..z <= len z by FINSEQ_3:25;
    z/.((W-min L~z)..z) = z.((W-min L~z)..z) by A5,PARTFUN1:def 6
      .= W-min L~z by A3,FINSEQ_4:19;
    then (W-min L~z)..z <> len z by A4,Th58;
    hence thesis by A6,XXREAL_0:1;
  end;
  suppose
A7: N-min L~z <> W-max L~z;
    (W-max L~z)..z in dom z by A2,FINSEQ_4:20;
    then (W-max L~z)..z <= len z by FINSEQ_3:25;
    hence thesis by A1,A7,Th75,XXREAL_0:2;
  end;
end;
