reserve A,B for Ordinal,
        o for object,
        x,y,z for Surreal,
        n for Nat,
        r,r1,r2 for Real;

theorem Th76:
  for r be Sequence of REAL
    for y,s1,s2 be Sequence
      for alpha be Ordinal st
    s1.alpha is uSurreal & s2.alpha is uSurreal &
    s1|alpha = s2|alpha &
    s1,y,r simplest_on_position alpha &
    s2,y,r simplest_on_position alpha
  holds
    s1.alpha = s2.alpha
proof
  let r be Sequence of REAL;
  let y,s1,s2 be Sequence;
  let alpha be Ordinal such that
A1: s1.alpha is uSurreal & s2.alpha is uSurreal and
A2: s1|alpha = s2|alpha and
A3: s1,y,r simplest_on_position alpha &
  s2,y,r simplest_on_position alpha and
A4:s1.alpha <> s2.alpha;
  reconsider s1a=s1.alpha,s2a=s2.alpha as uSurreal by A1;
  per cases;
  suppose alpha = 0;
    then s1.alpha = 0_No = s2.alpha by A1,A3;
    hence thesis by A4;
  end;
  suppose
A5: alpha <>0;
    s1a in_meets_terms s1,y,r,alpha by A3;
    then s1a in_meets_terms s2,y,r,alpha by A2,Th75;
    then
A6: born s2a in born s1a by A4,A3,A5;
    s2a in_meets_terms s2,y,r,alpha by A3;
    then s2a in_meets_terms s1,y,r,alpha by A2,Th75;
    hence thesis by A6,A4,A3,A5;
  end;
end;
