reserve n for Nat,
  i,j for Nat,
  r,s,r1,s1,r2,s2,r9,s9 for Real,
  p,q for Point of TOP-REAL 2,
  G for Go-board,
  x,y for set,
  v for Point of Euclid 2;

theorem
  1 < len G & 1 < width G implies LSeg(G*(len G,width G)+|[1,1]|, 1/2*(G
*(len G,width G)+G*(len G,width G -' 1))+|[1,0]|) c= Int cell(G,len G,width G)
  \/ Int cell(G,len G,width G -' 1) \/ { G*(len G,width G)+|[1,0]| }
proof
  assume that
A1: 1 < len G and
A2: 1 < width G;
  set q2 = G*(len G,width G), q3 = G*(len G,width G -' 1), r = 1/(1/2*(q2`2-q3
  `2)+1);
A3: width G -' 1 + 1 = width G by A2,XREAL_1:235;
  then
A4: width G -' 1 >= 1 by A2,NAT_1:13;
A5: width G -' 1 < width G by A3,NAT_1:13;
  then q3`2 < q2`2 by A1,A4,GOBOARD5:4;
  then
A6: q2`2-q3`2 > 0 by XREAL_1:50;
  then 1 < 1/2*(q2`2-q3`2)+1 by XREAL_1:29,129;
  then
A7: r < 1 by XREAL_1:212;
A8: q2`1 = G*(len G,1)`1 by A1,A2,GOBOARD5:2
    .= q3`1 by A1,A4,A5,GOBOARD5:2;
A9: ((1-r)*(q2+|[1,1]|)+r*(1/2*(q2+q3)+|[1,0]|))`1 = ((1-r)*(q2+|[1,1]|))`1
  +(r*(1/2*(q2+q3)+|[1,0]|))`1 by Lm1
    .= (1-r)*(q2+|[1,1]|)`1+(r*(1/2*(q2+q3)+|[1,0]|))`1 by Lm3
    .= (1-r)*(q2+|[1,1]|)`1+r*(1/2*(q2+q3)+|[1,0]|)`1 by Lm3
    .= (1-r)*(q2`1+|[1,1]|`1)+r*(1/2*(q2+q3)+|[1,0]|)`1 by Lm1
    .= (1-r)*(q2`1+|[1,1]|`1)+r*((1/2*(q2+q3))`1+|[1,0]|`1) by Lm1
    .= (1-r)*(q2`1+1)+r*((1/2*(q2+q3))`1+|[1,0]|`1) by EUCLID:52
    .= (1-r)*q2`1+(1-r)*1+r*((1/2*(q2+q3))`1+1) by EUCLID:52
    .= (1-r)*q2`1+r*(1/2*(q2+q3))`1+((1-r)+r)
    .= (1-r)*q2`1+r*(1/2*(q2+q3)`1)+1 by Lm3
    .= (1-r)*q2`1+r*(1/2*(q2`1+q2`1))+1 by A8,Lm1
    .= q2`1+|[1,0]|`1 by EUCLID:52
    .= (q2+|[1,0]|)`1 by Lm1;
A10: r*((1/2)*q2`2)-r*((1/2)*q3`2)+r = r*((1/2)*(q2`2-q3`2)+1)
    .= 1 by A6,XCMPLX_1:106;
  ((1-r)*(q2+|[1,1]|)+r*(1/2*(q2+q3)+|[1,0]|))`2 = ((1-r)*(q2+|[1,1]|))`2
  +(r*(1/2*(q2+q3)+|[1,0]|))`2 by Lm1
    .= ((1-r)*q2+(1-r)*|[1,1]|)`2+(r*(1/2*(q2+q3)+|[1,0]|))`2 by RLVECT_1:def 5
    .= ((1-r)*q2)`2+((1-r)*|[1,1]|)`2+(r*(1/2*(q2+q3)+|[1,0]|))`2 by Lm1
    .= ((1-r)*q2)`2+(1-r)*|[1,1]|`2+(r*(1/2*(q2+q3)+|[1,0]|))`2 by Lm3
    .= ((1-r)*q2)`2+(1-r)*1+(r*(1/2*(q2+q3)+|[1,0]|))`2 by EUCLID:52
    .= (1-r)*q2`2+(1-r)+(r*(1/2*(q2+q3)+|[1,0]|))`2 by Lm3
    .= (1-r)*q2`2+(1-r)+r*(1/2*(q2+q3)+|[1,0]|)`2 by Lm3
    .= (1-r)*q2`2+(1-r)+r*((1/2*(q2+q3))`2+|[1,0]|`2) by Lm1
    .= (1-r)*q2`2+(1-r)+r*((1/2*(q2+q3))`2+0) by EUCLID:52
    .= (1-r)*q2`2+(1-r)+r*(1/2*(q2+q3)`2) by Lm3
    .= (1-r)*q2`2+(1-r)+r*(1/2*(q2`2+q3`2)) by Lm1
    .= q2`2+0 by A10
    .= q2`2+|[1,0]|`2 by EUCLID:52
    .= (q2+|[1,0]|)`2 by Lm1;
  then
  (1-r)*(q2+|[1,1]|)+r*(1/2*(q2+q3)+|[1,0]|) = |[(q2+|[1,0]|)`1,(q2+|[1,0
  ]|)`2]| by A9,EUCLID:53
    .= q2+|[1,0]| by EUCLID:53;
  then q2+|[1,0]| in LSeg(q2+|[1,1]|,1/2*(q2+q3)+|[1,0]|) by A6,A7;
  then
A11: LSeg(q2+|[1,1]|,1/2*(q2+q3)+|[1,0]|) = LSeg(q2+|[1,1]|,q2+|[1,0]|) \/
  LSeg(q2+|[1,0]|,1/2*(q2+q3)+|[1,0]|) by TOPREAL1:5;
  set I1 = Int cell(G,len G,width G), I2 = Int cell(G,len G,width G -' 1);
A12: I1 \/ I2 \/ { q2+|[1,0]| } = I1 \/ (I2 \/ ({ q2+|[1,0]| } \/ { q2+|[1,0
  ]| })) by XBOOLE_1:4
    .= I1 \/ (I2 \/ { q2+|[1,0]| } \/ { q2+|[1,0]| }) by XBOOLE_1:4
    .= I1 \/ { q2+|[1,0]| } \/ (I2 \/ { q2+|[1,0]| }) by XBOOLE_1:4;
A13: LSeg(q2+|[1,1]|,q2+|[1,0]|) c= I1 \/ { q2+|[1,0]| } by Th59;
  LSeg(q2+|[1,0]|,1/2*(q2+q3)+|[1,0]|) c= I2 \/ { q2+|[1,0]| } by A3,A4,A5,Th51
;
  hence thesis by A11,A13,A12,XBOOLE_1:13;
end;
