reserve x,O for set,
  o for Element of O,
  G,H,I for GroupWithOperators of O,
  A, B for Subset of G,
  N for normal StableSubgroup of G,
  H1,H2,H3 for StableSubgroup of G,
  g1,g2 for Element of G,
  h1,h2 for Element of H1,
  h for Homomorphism of G,H;
reserve E for set,
  A for Action of O,E,
  C for Subset of G,
  N1 for normal StableSubgroup of H1;

theorem Th77:
  the carrier of H1 = the carrier of N1 implies H1./.N1 is trivial
proof
  reconsider N19 = the multMagma of N1 as strict normal Subgroup of H1 by Lm6;
  assume
A1: the carrier of H1 = the carrier of N1;
  now
    let x be object;
    hereby
      assume
A2:   x in Left_Cosets N19;
      then reconsider A=x as Subset of H1;
      consider a be Element of H1 such that
A3:   A = a * N19 by A2,GROUP_2:def 15;
      A = a * [#]the carrier of H1 by A1,A3;
      hence x = the carrier of H1 by GROUP_2:17;
    end;
    the carrier of H1 = 1_H1 * [#]the carrier of H1 by GROUP_2:17;
    then
A4: the carrier of H1 = 1_H1 * N19 by A1;
    assume x = the carrier of H1;
    hence x in Left_Cosets N19 by A4,GROUP_2:def 15;
  end;
  then
A5: {the carrier of H1} = Left_Cosets N19 by TARSKI:def 1;
  Cosets N1 = Cosets N19 by Def14;
  hence thesis by A5;
end;
