reserve m,n,i,i2,j for Nat,
  r,r1,r2,s,t for Real,
  x,y,z for object;
reserve p,p1,p2,p3,q,q1,q2,q3,q4 for Point of TOP-REAL n;
reserve u for Point of Euclid n;
reserve R for Subset of TOP-REAL n;
reserve P,Q for Subset of TOP-REAL n;

theorem Th61:
  for R being Subset of TOP-REAL n holds p in R & P={q: q=p or ex
f being Function of I[01],TOP-REAL n st f is continuous & rng f c= R & f.0=p &
  f.1=q} implies P c= R
proof
  let R be Subset of TOP-REAL n;
  assume that
A1: p in R and
A2: P = {q: q=p or ex f being Function of I[01],TOP-REAL n st f is
  continuous & rng f c= R & f.0=p & f.1=q};
  let x be object;
  assume x in P;
  then consider q such that
A3: q=x and
A4: q=p or ex f being Function of I[01],TOP-REAL n st f is continuous &
  rng f c= R & f.0=p & f.1=q by A2;
  per cases by A4;
  suppose
    q=p;
    hence thesis by A1,A3;
  end;
  suppose
    ex f being Function of I[01],TOP-REAL n st f is continuous & rng f
    c= R & f.0=p & f.1=q;
    then consider f1 being Function of I[01],TOP-REAL n such that
    f1 is continuous and
A5: rng f1 c= R and
    f1.0=p and
A6: f1.1=q;
    reconsider P1=rng f1 as Subset of TOP-REAL n;
    dom f1=[.0,1.] by BORSUK_1:40,FUNCT_2:def 1;
    then 1 in dom f1 by XXREAL_1:1;
    then q in P1 by A6,FUNCT_1:def 3;
    hence thesis by A3,A5;
  end;
end;
