
theorem Th77:
  for X be non empty set, S be SigmaField of X, M be sigma_Measure
  of S, f be PartFunc of X,ExtREAL st f is_simple_func_in S & f is nonnegative
  holds integral+(M,f) =integral'(M,f)
proof
  let X be non empty set, S be SigmaField of X, M be sigma_Measure of S, f be
  PartFunc of X,ExtREAL such that
A1: f is_simple_func_in S and
A2: f is nonnegative;
  deffunc PF(Nat) = f;
  consider F be Functional_Sequence of X,ExtREAL such that
A3: for n be Nat holds F.n=PF(n) from SEQFUNC:sch 1;
A4: for n,m be Nat st n <=m holds for x be Element of X st x in dom f holds
  (F.n).x <= (F.m).x
  proof
    let n,m be Nat;
    assume n<=m;
    let x be Element of X;
    assume x in dom f;
    (F.n).x=f.x by A3;
    hence thesis by A3;
  end;
  deffunc PK(Nat) = integral'(M,(F.$1));
  consider K be sequence of ExtREAL such that
A5: for n be Element of NAT holds K.n = PK(n) from FUNCT_2:sch 4;
A6: now
    let n be Nat;
    n in NAT by ORDINAL1:def 12;
    hence K.n=PK(n) by A5;
  end;
A7: for n be Nat holds K.n=integral'(M,f)
  proof
    let n be Nat;
    thus K.n=integral'(M,F.n) by A6
      .=integral'(M,f) by A3;
  end;
  then
A8: lim K=integral'(M,f) by Th60;
  ex GF be Finite_Sep_Sequence of S st dom f = union rng GF & for n being
Nat,x,y being Element of X st n in dom GF & x in GF.n & y in GF.n holds f.x = f
  .y by A1,MESFUNC2:def 4;
  then reconsider A=dom f as Element of S by MESFUNC2:31;
A9: f is A-measurable by A1,MESFUNC2:34;
A10: for x be Element of X st x in dom f holds F#x is convergent & lim(F#x)
  = f.x
  proof
    let x be Element of X;
    assume x in dom f;
    now
      let n be Nat;
      thus (F#x).n = (F.n).x by Def13
        .=f.x by A3;
    end;
    hence thesis by Th60;
  end;
A11: for n be Nat holds F.n is nonnegative by A2,A3;
A12: for n be Nat holds F.n is_simple_func_in S & dom(F.n) = dom f by A1,A3;
  K is convergent by A7,Th60;
  hence thesis by A2,A9,A6,A12,A11,A4,A10,A8,Def15;
end;
