reserve p,q for Rational;
reserve g,m,m1,m2,n,n1,n2 for Nat;
reserve i,i1,i2,j,j1,j2 for Integer;
reserve R for Ring, F for Field;

theorem Th76:
for n being positive Nat holds Char(Z/n) = n
proof
let n be positive Nat;
set R = Z/n;
per cases by NAT_1:25;
suppose A1: n = 1;
 then A2: 1 '*' 1.R = 0.R by Th59,INT_3:10;
 for n being positive Nat st n<1 holds n'*'1.R <>0.R by NAT_1:14;
 hence thesis by A2,A1,Def5;
 end;
suppose A3: n > 1;
 reconsider m = n-1 as Nat;
 n-1 < n-0 by XREAL_1:15; then
 reconsider mm = m as Element of Segm(n) by NAT_1:44;
 reconsider e = 1 as Element of Segm(n) by A3,NAT_1:44;
 A4: 1 '*' 1.R = 1.R by Th59 .= 1 by INT_3:14,A3;
 A5: for k being Nat st k <= m holds k '*' 1.R = k
     proof
     let k be Nat;
     assume A6: k <= m;
     defpred P[Nat] means ($1) '*' 1.R = ($1);
     reconsider u = m as Element of NAT by INT_1:3;
     0 '*' 1.R = 0.R by Th58
              .= 0 by NAT_1:44,SUBSET_1:def 8;
     then A7: P[0];
     A8: for k being Element of NAT st 0<=k & k<u holds P[k] implies P[k+1]
        proof
        let k be Element of NAT;
        assume A9: 0 <= k & k < u;
        assume A10: P[k];
        reconsider z = k '*' 1.R as Element of Segm(n);
        A11: k+1 < m+1 by A9,XREAL_1:6;
        (k+1) '*' 1.R = (k '*' 1.R) + 1.R by Lm5
                     .= (k '*' 1.R) + (1 '*' 1.R) by Th59
                     .= k+1 by INT_3:7,A11,A10,A4;
        hence P[k+1];
        end;
     A12: for i being Element of NAT st 0 <= i & i <= u holds P[i]
        from INT_1:sch 7(A7,A8);
     k is Element of NAT by INT_1:3;
     hence thesis by A12,A6;
     end;
 A13: n '*' 1.R = (m+1) '*' 1.R
          .= (m '*' 1.R) + 1.R by Lm5
          .= (m '*' 1.R) + (1 '*' 1.R) by Th59
          .= (addint(n)).(mm,e) by A4,A5
          .= (m+1) mod n by GR_CY_1:def 4
          .= 0 by INT_1:50
          .= 0.R by NAT_1:44,SUBSET_1:def 8;
 now let k be positive Nat;
   assume k < n;
   then k < m+1;
   then A14: k <= m by NAT_1:13;
   now assume k '*' 1.R = 0.R;
     then k = 0.R by A5,A14
           .= 0 by NAT_1:44,SUBSET_1:def 8;
     hence contradiction;
     end;
   hence k '*' 1.R <> 0.R;
   end;
 hence thesis by A13,Def5;
 end;
end;
