reserve a, b, c, d, x, y, z for Complex;
reserve r for Real;

theorem Th76:
  a <> b & b <> c implies angle(a,b,c) = angle(Rotate(a,r), Rotate
  (b,r), Rotate(c,r))
proof
  set cb = c-b, ab = a-b;
  set rc = Rotate(c,r), rb = Rotate(b,r), ra = Rotate(a,r);
  set rcb = Rotate(c,r)-Rotate(b,r), rab = Rotate(a,r)-Rotate(b,r);
  assume that
A1: a <> b and
A2: b <> c;
A3: 0 <= angle(a,b,c) & angle(a,b,c) < 2*PI by Th68;
  cb <> 0 by A2;
  then consider cbi being Integer such that
A4: Arg(Rotate(cb,r)) = 2*PI*cbi+(r+Arg(cb)) by Th52;
  ab <> 0 by A1;
  then consider abi being Integer such that
A5: Arg(Rotate(ab,r)) = 2*PI*abi+(r+Arg(ab)) by Th52;
A6: 0 <= angle(Rotate(a,r),Rotate(b,r), Rotate(c,r)) & angle(Rotate(a,r),
  Rotate( b,r), Rotate(c,r))< 2*PI by Th68;
  rab = Rotate(ab,r) by Th57;
  then
A7: Arg(rcb)-Arg(rab) = 2*PI*cbi+r+Arg(cb) - (2*PI*abi+r+Arg(ab)) by A5,A4,Th57
    .= Arg(cb)-Arg(ab)+2*PI*(cbi-abi);
  per cases;
  suppose
    Arg(c-b)-Arg(a-b) >= 0;
    then
A8: angle(a,b,c) = Arg(c-b)-Arg(a-b) by Def4;
    thus angle(a,b,c) = angle(Rotate(a,r),Rotate(b,r), Rotate(c,r))
    proof
      per cases;
      suppose
        Arg(rcb)-Arg(rab) >= 0;
        then angle(ra,rb,rc) = Arg(rcb)-Arg(rab) by Def4;
        hence thesis by A3,A6,A7,A8,Th2;
      end;
      suppose
        Arg(rcb)-Arg(rab) < 0;
        then angle(ra,rb,rc) = Arg(cb)-Arg(ab)+2*PI*(cbi-abi)+2*PI by A7,Def4
          .= Arg(cb)-Arg(ab)+2*PI*(cbi-abi+1);
        hence thesis by A3,A6,A8,Th2;
      end;
    end;
  end;
  suppose
    Arg(cb)-Arg(ab) < 0;
    then
A9: angle(a,b,c) = 2*PI+(Arg(cb)-Arg(ab)) by Def4;
    thus thesis
    proof
      per cases;
      suppose
        Arg(rcb)-Arg(rab) >= 0;
        then
        angle(ra,rb,rc) = 2*PI+(Arg(cb)-Arg(ab))+2*PI*(cbi-abi+-1) by A7,Def4;
        hence thesis by A3,A6,A9,Th2;
      end;
      suppose
        Arg(rcb)-Arg(rab) < 0;
        then angle(ra,rb,rc) = Arg(cb)-Arg(ab)+2*PI*(cbi-abi)+2*PI by A7,Def4
          .= 2*PI+(Arg(cb)-Arg(ab))+2*PI*(cbi-abi);
        hence thesis by A3,A6,A9,Th2;
      end;
    end;
  end;
end;
