reserve x,y for set,
  i for Nat;
reserve V for non empty CLSStruct,
  u,v,v1,v2,v3 for VECTOR of V,
  A for Subset of V,
  l, l1, l2 for C_Linear_Combination of A,
  x,y,y1,y2 for set,
  a,b for Complex,
  F for FinSequence of the carrier of V,
  f for Function of the carrier of V, COMPLEX;
reserve K,L,L1,L2,L3 for C_Linear_Combination of V;
reserve e,e1,e2 for Element of C_LinComb V;

theorem
  for V being ComplexUnitarySpace-like non empty CUNITSTR, M being
Subset of V, v being VECTOR of V, r being Real st M = {u where u is VECTOR of V
  : |.u .|. v .| <= r } holds M is convex
proof
  let V be ComplexUnitarySpace-like non empty CUNITSTR;
  let M be Subset of V;
  let v be VECTOR of V;
  let r be Real;
  assume
A1: M = {u where u is VECTOR of V : |.u.|.v.| <= r };
  let x,y be VECTOR of V;
  let s be Complex;
  assume that
A2: ex p being Real st s=p & 0 < p & p < 1 and
A3: x in M and
A4: y in M;
  consider p being Real such that
A5: s=p and
A6: 0 < p and
A7: p < 1 by A2;
A8: 1-p > 0 by A7,XREAL_1:50;
  ex u2 be VECTOR of V st y = u2 & |.u2.|.v.| <= r by A1,A4;
  then
A9: (1-p)*|.y.|.v.| <= (1-p)*r by A8,XREAL_1:64;
  ex u1 be VECTOR of V st x = u1 & |.u1.|.v.| <= r by A1,A3;
  then p*|.x.|.v.| <= p*r by A6,XREAL_1:64;
  then
A10: p*|.x.|.v.|+(1-p)*|.y.|.v.| <= p*r + (1-p)*r by A9,XREAL_1:7;
  |.s*(x.|.v).| = p*|.x.|.v.| & |.(1r-s)*(y.|.v).| = (1-p)*|.y.|.v.| by A5,A6
,A7,Th44;
  then
A11: |.s*(x.|.v)+(1r-s)*(y.|.v).| <= p*|.x.|.v.| + (1-p)*|.y.|.v.| by
COMPLEX1:56;
  |.(s*x+(1r-s)*y).|.v.| = |.(s*x).|.v+((1r-s)*y).|.v.| by CSSPACE:def 13
    .= |.s*(x.|.v)+((1r-s)*y).|.v.| by CSSPACE:def 13
    .= |. s*(x.|.v)+(1r-s)*(y.|.v).| by CSSPACE:def 13;
  then |.(s*x+(1r-s)*y).|.v.| <= r by A11,A10,XXREAL_0:2;
  hence thesis by A1;
end;
