reserve f for Function;
reserve p,q for FinSequence;
reserve A,B,C for set,x,x1,x2,y,z for object;
reserve k,l,m,n for Nat;
reserve a for Nat;
reserve D for non empty set;
reserve d,d1,d2,d3 for Element of D;
reserve L,M for Element of NAT;
reserve f for Function of A,B;
reserve f for Function;
reserve x1,x2,x3,x4,x5 for object;
reserve p for FinSequence;

theorem Th77:
  p = <*x1,x2,x3,x4,x5*> iff
  len p = 5 & p.1 = x1 & p.2 = x2 & p.3 = x3 & p.4 = x4 & p.5 = x5
proof
  set p4=<*x1,x2,x3,x4*>;
  thus p = <*x1,x2,x3,x4,x5*> implies len p = 5 & p.1 = x1 & p.2 = x2 & p.3 =
  x3 & p.4 = x4 & p.5 = x5
  proof
    set p4=<*x1,x2,x3,x4*>;
    1 in {1} by TARSKI:def 1;
    then
A1: 1 in dom <*x5*> by FINSEQ_1:2,def 8;
    assume
A2: p =<*x1,x2,x3,x4,x5*>;
    then
A3: p = (p4^<*x5*>) by Th75;
    thus len p = len (<*x1,x2,x3,x4*>^<*x5*>) by A2,Th75
      .=len <*x1,x2,x3,x4*> + len <*x5*> by FINSEQ_1:22
      .=4 + len <*x5*> by Th76
      .=4+1 by FINSEQ_1:40
      .=5;
A4: dom p4 ={1,2,3,4} by FINSEQ_1:89,FINSEQ_3:2;
    then 1 in dom p4 by ENUMSET1:def 2;
    hence p.1 = p4.1 by A3,FINSEQ_1:def 7
      .=x1;
    2 in dom p4 by A4,ENUMSET1:def 2;
    hence p.2 = p4.2 by A3,FINSEQ_1:def 7
      .=x2;
    3 in dom p4 by A4,ENUMSET1:def 2;
    hence p.3 = p4.3 by A3,FINSEQ_1:def 7
      .=x3;
    4 in dom p4 by A4,ENUMSET1:def 2;
    hence p.4 = p4.4 by A3,FINSEQ_1:def 7
      .=x4;
    thus p.5 = (p4^<*x5*>).(4+1) by A2,Th75
      .=(p4^<*x5*>).(len p4+ 1) by Th76
      .= <*x5*>.1 by A1,FINSEQ_1:def 7
      .= x5;
  end;
  assume that
A5: len p = 5 and
A6: p.1 = x1 and
A7: p.2 = x2 and
A8: p.3 = x3 and
A9: p.4=x4 and
A10: p.5=x5;
A11: for k be Nat st k in dom p4 holds p.k=p4.k
  proof
A12: len p4 = 4 by Th76;
    let k be Nat;
    assume k in dom p4;
    then
A13: k in {1,2,3,4} by A12,FINSEQ_1:def 3,FINSEQ_3:2;
    per cases by A13,ENUMSET1:def 2;
    suppose
      k=1;
      hence thesis by A6;
    end;
    suppose
      k=2;
      hence thesis by A7;
    end;
    suppose
      k=3;
      hence thesis by A8;
    end;
    suppose
      k=4;
      hence thesis by A9;
    end;
  end;
A14: for k be Nat st k in dom <*x5*> holds p.( len p4 + k) = <*x5*>.k
  proof
    let k be Nat;
    assume k in dom <*x5*>;
    then k in {1} by FINSEQ_1:2,def 8;
    then
A15: k = 1 by TARSKI:def 1;
    hence p.( len p4 + k) = p.(4+1) by Th76
      .=<*x5*>.k by A10,A15;
  end;
  dom p = Seg(4+1) by A5,FINSEQ_1:def 3
    .= Seg(len p4 + 1) by Th76
    .= Seg(len p4 + len <*x5*>) by FINSEQ_1:39;
  hence p=p4^<*x5*> by A11,A14,FINSEQ_1:def 7
    .=<*x1,x2,x3,x4,x5*> by Th75;
end;
