reserve x,O for set,
  o for Element of O,
  G,H,I for GroupWithOperators of O,
  A, B for Subset of G,
  N for normal StableSubgroup of G,
  H1,H2,H3 for StableSubgroup of G,
  g1,g2 for Element of G,
  h1,h2 for Element of H1,
  h for Homomorphism of G,H;
reserve E for set,
  A for Action of O,E,
  C for Subset of G,
  N1 for normal StableSubgroup of H1;

theorem Th78:
  for G,H being GroupWithOperators of O, N being StableSubgroup of
G, H9 being strict StableSubgroup of H, f being Homomorphism of G,H st N = Ker
  f holds ex G9 being strict StableSubgroup of G st the carrier of G9 = f"(the
carrier of H9) & (H9 is normal implies N is normal StableSubgroup of G9 & G9 is
  normal)
proof
  let G,H be GroupWithOperators of O;
  let N be StableSubgroup of G;
  let H9 be strict StableSubgroup of H;
  reconsider H99 = the multMagma of H9 as strict Subgroup of H by Lm15;
  let f be Homomorphism of G,H;
  assume
A1: N = Ker f;
  set A = {g where g is Element of G:f.g in H99};
A2: 1_H in H99 by GROUP_2:46;
  then f.(1_G) in H99 by Lm12;
  then 1_G in A;
  then reconsider A as non empty set;
  now
    let x be object;
    assume x in A;
    then ex g be Element of G st x=g & f.g in H99;
    hence x in the carrier of G;
  end;
  then reconsider A as Subset of G by TARSKI:def 3;
A3: now
    let g1,g2 be Element of G;
    assume that
A4: g1 in A and
A5: g2 in A;
    consider b be Element of G such that
A6: b=g2 and
A7: f.b in H99 by A5;
    consider a be Element of G such that
A8: a=g1 and
A9: f.a in H99 by A4;
    set fb = f.b;
    set fa = f.a;
    f.(a*b) = f.a * f.b & fa * fb in H99 by A9,A7,GROUP_2:50,GROUP_6:def 6;
    hence g1*g2 in A by A8,A6;
  end;
A10: now
    let o be Element of O;
    let g be Element of G;
    assume g in A;
    then consider a be Element of G such that
A11: a=g and
A12: f.a in H99;
    f.a in the carrier of H99 by A12,STRUCT_0:def 5;
    then f.a in H9 by STRUCT_0:def 5;
    then (H^o).(f.g) in H9 by A11,Lm9;
    then f.((G^o).g) in H9 by Def18;
    then f.((G^o).g) in the carrier of H9 by STRUCT_0:def 5;
    then f.((G^o).g) in H99 by STRUCT_0:def 5;
    hence (G^o).g in A;
  end;
  now
    let g be Element of G;
    assume g in A;
    then consider a be Element of G such that
A13: a=g and
A14: f.a in H99;
    (f.a)" in H99 by A14,GROUP_2:51;
    then f.(a") in H99 by Lm13;
    hence g" in A by A13;
  end;
  then consider G99 be strict StableSubgroup of G such that
A15: the carrier of G99 = A by A3,A10,Lm14;
  take G99;
  now
    reconsider R = f as Relation of the carrier of G, the carrier of H;
    let g be Element of G;
    hereby
      assume g in A;
      then ex a be Element of G st a=g & f.a in H99;
      then
A16:  f.g in the carrier of H9 by STRUCT_0:def 5;
      dom f = the carrier of G by FUNCT_2:def 1;
      then [g,f.g] in f by FUNCT_1:1;
      hence g in f"(the carrier of H9) by A16,RELSET_1:30;
    end;
    assume g in f"(the carrier of H9);
    then consider h be Element of H such that
A17: [g,h] in R & h in (the carrier of H9) by RELSET_1:30;
    f.g=h & h in H99 by A17,FUNCT_1:1,STRUCT_0:def 5;
    hence g in A;
  end;
  hence the carrier of G99 = f"(the carrier of H9) by A15,SUBSET_1:3;
  reconsider G9 = the multMagma of G99 as strict Subgroup of G by Lm15;
  now
    assume
A18: H9 is normal;
    now
      let g be Element of G;
      assume g in N;
      then f.g = 1_H by A1,Th47;
      then g in the carrier of G99 by A2,A15;
      hence g in G99 by STRUCT_0:def 5;
    end;
    hence N is normal StableSubgroup of G99 by A1,Th13,Th40;
    now
      let g be Element of G;
      now
        H99 is normal by A18;
        then
A19:    H99 |^ (f.g)" = H99 by GROUP_3:def 13;
        let x be object;
        assume x in g * G9;
        then consider h be Element of G such that
A20:    x=g*h and
A21:    h in A by A15,GROUP_2:27;
        set h9=g*h*g";
A22:    f.h9 = f.(g*h) * f.(g") by GROUP_6:def 6
          .= f.g * f.h * f.(g") by GROUP_6:def 6
          .= ((f.g)")" * f.h * (f.g)" by Lm13
          .= f.h |^ (f.g)" by GROUP_3:def 2;
        ex a be Element of G st a=h & f.a in H99 by A21;
        then f.h9 in H99 by A19,A22,GROUP_3:58;
        then
A23:    h9 in A;
        h9*g = (g*h)*(g"*g) by GROUP_1:def 3
          .= (g*h)*1_G by GROUP_1:def 5
          .= x by A20,GROUP_1:def 4;
        hence x in G9 * g by A15,A23,GROUP_2:28;
      end;
      hence g * G9 c= G9 * g;
    end;
    then for H being strict Subgroup of G st H = the multMagma of G99 holds H
    is normal by GROUP_3:118;
    hence G99 is normal;
  end;
  hence thesis;
end;
