
theorem
  for R being left_zeroed right_zeroed left_add-cancelable
  left-distributive non empty doubleLoopStr, I being non empty Subset of R
  holds {0.R} *' I = {0.R}
proof
  let R be left_zeroed right_zeroed left_add-cancelable left-distributive non
  empty doubleLoopStr, I be non empty Subset of R;
A1: now
    let u be object;
    assume u in ({0.R}) *' I;
    then consider s being FinSequence of the carrier of R such that
A2: Sum s = u and
A3: for i being Element of NAT st 1 <= i & i <= len s ex a,b being
    Element of R st s.i = a*b & a in {0.R} & b in I;
    now
      per cases;
      case
        len s = 0;
        then s = <*>(the carrier of R);
        hence Sum s = 0.R by RLVECT_1:43;
      end;
      case
        len s <> 0;
        then 1 <= len s by NAT_1:14;
        then 1 in Seg(len s) by FINSEQ_1:1;
        then
A4:     1 in dom s by FINSEQ_1:def 3;
A5:     for i being Element of NAT st i in dom s holds s/.i = 0.R
        proof
          let i be Element of NAT;
          assume
A6:       i in dom s;
          then i in Seg(len s) by FINSEQ_1:def 3;
          then 1 <= i & i <= len s by FINSEQ_1:1;
          then consider a,b being Element of R such that
A7:       s.i = a*b and
A8:       a in {0.R} and
          b in I by A3;
A9:       a = 0.R by A8,TARSKI:def 1;
          s/.i = a*b by A6,A7,PARTFUN1:def 6;
          hence thesis by A9,BINOM:1;
        end;
        then
        for i being Element of NAT st i in dom s & i <> 1 holds s/.i = 0. R;
        hence Sum s = s/.1 by A4,POLYNOM2:3
          .= 0.R by A4,A5;
      end;
    end;
    hence u in {0.R} by A2,TARSKI:def 1;
  end;
  now
    reconsider o = 0.R as Element of {0.R} by TARSKI:def 1;
    set a = the Element of I;
    let u be object;
    assume
A10: u in {0.R};
    set q = <* 0.R*a *>;
A11: len q = 1 & q.1 = 0.R*a by FINSEQ_1:40;
A12: for i being Element of NAT st 1 <= i & i <= len q holds ex b,r being
    Element of R st q.i = b*r & b in {0.R} & r in I
    proof
      let i be Element of NAT;
      assume 1 <= i & i <= len q;
      then q.i = o*a by A11,XXREAL_0:1;
      hence thesis;
    end;
    Sum q = 0.R*a by BINOM:3
      .= 0.R by BINOM:1
      .= u by A10,TARSKI:def 1;
    hence u in {0.R} *' I by A12;
  end;
  hence thesis by A1,TARSKI:2;
end;
