reserve a for Real;
reserve p,q for Point of TOP-REAL 2;

theorem Th78:
  for cn being Real,q1,q2 being Point of TOP-REAL 2 st -1<cn & q1
`2>0 & q1`1/|.q1.|<cn & q2`2>0 & q2`1/|.q2.|<cn & q1`1/|.q1.|<q2`1/|.q2.| holds
for p1,p2 being Point of TOP-REAL 2 st p1=(cn-FanMorphN).q1 & p2=(cn-FanMorphN)
  .q2 holds p1`1/|.p1.|<p2`1/|.p2.|
proof
  let cn be Real,q1,q2 be Point of TOP-REAL 2;
  assume that
A1: -1<cn and
A2: q1`2>0 and
A3: q1`1/|.q1.|<cn and
A4: q2`2>0 and
A5: q2`1/|.q2.|<cn and
A6: q1`1/|.q1.|<q2`1/|.q2.|;
A7: q1`1/|.q1.|-cn< q2`1/|.q2.|-cn & 1+cn>0 by A1,A6,XREAL_1:9,148;
  let p1,p2 be Point of TOP-REAL 2;
  assume that
A8: p1=(cn-FanMorphN).q1 and
A9: p2=(cn-FanMorphN).q2;
A10: |.p2.|=|.q2.| by A9,Th66;
  p2=|[ |.q2.|* ((q2`1/|.q2.|-cn)/(1+cn)), |.q2.|*( sqrt(1-((q2`1/|.q2.|-
  cn)/(1+cn))^2))]| by A4,A5,A9,Th50;
  then
A11: p2`1= |.q2.|* ((q2`1/|.q2.|-cn)/(1+cn)) by EUCLID:52;
  |.q2.|>0 by A4,Lm1,JGRAPH_2:3;
  then
A12: p2`1/|.p2.|= ((q2`1/|.q2.|-cn)/(1+cn)) by A11,A10,XCMPLX_1:89;
  p1=|[ |.q1.|* ((q1`1/|.q1.|-cn)/(1+cn)), |.q1.|*( sqrt(1-((q1`1/|.q1.|-
  cn)/(1+cn))^2))]| by A2,A3,A8,Th50;
  then
A13: p1`1= |.q1.|* ((q1`1/|.q1.|-cn)/(1+cn)) by EUCLID:52;
A14: |.p1.|=|.q1.| by A8,Th66;
  |.q1.|>0 by A2,Lm1,JGRAPH_2:3;
  then p1`1/|.p1.|= ((q1`1/|.q1.|-cn)/(1+cn)) by A13,A14,XCMPLX_1:89;
  hence thesis by A12,A7,XREAL_1:74;
end;
