reserve p,p1,p2,p3,q,q1,q2 for Point of TOP-REAL 2,
  i for Nat,
  lambda for Real;

theorem Th78:
  for p1,p2,p3,p4 being Point of TOP-REAL 2,
  P being non empty compact Subset of TOP-REAL 2,
  f being Function of TOP-REAL 2,TOP-REAL 2 st P= circle(0,0,1) & f=Sq_Circ
  holds p1,p2,p3,p4 are_in_this_order_on rectangle(-1,1,-1,1)
  iff f.p1,f.p2,f.p3,f.p4 are_in_this_order_on P
proof
  let p1,p2,p3,p4 be Point of TOP-REAL 2,
  P be non empty compact Subset of TOP-REAL 2,
  f be Function of TOP-REAL 2,TOP-REAL 2;
  set K = rectangle(-1,1,-1,1);
  assume that
A1: P= circle(0,0,1) and
A2: f=Sq_Circ;
A3: K is being_simple_closed_curve by Th50;
  circle(0,0,1)={p5 where p5 is Point of TOP-REAL 2: |.p5.|=1} by Th24;
  then
A4: P is being_simple_closed_curve by A1,JGRAPH_3:26;
  thus p1,p2,p3,p4 are_in_this_order_on K implies
  f.p1,f.p2,f.p3,f.p4 are_in_this_order_on P
  proof
    assume
A5: p1,p2,p3,p4 are_in_this_order_on K;
    now per cases by A5,JORDAN17:def 1;
      case LE p1,p2,K & LE p2,p3,K & LE p3,p4,K;
        hence thesis by A1,A2,Th72;
      end;
      case LE p2,p3,K & LE p3,p4,K & LE p4,p1,K;
        hence thesis by A1,A2,A4,Th72,JORDAN17:12;
      end;
      case LE p3,p4,K & LE p4,p1,K & LE p1,p2,K;
        hence thesis by A1,A2,A4,Th72,JORDAN17:11;
      end;
      case LE p4,p1,K & LE p1,p2,K & LE p2,p3,K;
        hence thesis by A1,A2,A4,Th72,JORDAN17:10;
      end;
    end;
    hence thesis;
  end;
  thus f.p1,f.p2,f.p3,f.p4 are_in_this_order_on P implies
  p1,p2,p3,p4 are_in_this_order_on K
  proof
    assume
A6: f.p1,f.p2,f.p3,f.p4 are_in_this_order_on P;
    now per cases by A6,JORDAN17:def 1;
      case LE f.p1,f.p2,P & LE f.p2,f.p3,P & LE f.p3,f.p4,P;
        hence thesis by A1,A2,Th77;
      end;
      case LE f.p2,f.p3,P & LE f.p3,f.p4,P & LE f.p4,f.p1,P;
        then p2,p3,p4,p1 are_in_this_order_on K by A1,A2,Th77;
        hence thesis by A3,JORDAN17:12;
      end;
      case LE f.p3,f.p4,P & LE f.p4,f.p1,P & LE f.p1,f.p2,P;
        then p3,p4,p1,p2 are_in_this_order_on K by A1,A2,Th77;
        hence thesis by A3,JORDAN17:11;
      end;
      case LE f.p4,f.p1,P & LE f.p1,f.p2,P & LE f.p2,f.p3,P;
        then p4,p1,p2,p3 are_in_this_order_on K by A1,A2,Th77;
        hence thesis by A3,JORDAN17:10;
      end;
    end;
    hence thesis;
  end;
end;
