reserve m,n,i,i2,j for Nat,
  r,r1,r2,s,t for Real,
  x,y,z for object;
reserve p,p1,p2,p3,q,q1,q2,q3,q4 for Point of TOP-REAL n;
reserve u for Point of Euclid n;
reserve R for Subset of TOP-REAL n;
reserve P,Q for Subset of TOP-REAL n;

theorem Th62:
  for R being Subset of TOP-REAL n, p being Point of TOP-REAL n st
R is connected & R is open & p in R & P={q: q=p or ex f being Function of I[01]
  ,TOP-REAL n st f is continuous & rng f c= R & f.0=p & f.1=q} holds R c= P
proof
  let R be Subset of TOP-REAL n, p be Point of TOP-REAL n;
  assume that
A1: R is connected & R is open and
A2: p in R and
A3: P = {q: q=p or ex f being Function of I[01],TOP-REAL n st f is
  continuous & rng f c= R & f.0=p & f.1=q};
  reconsider R9 = R as non empty Subset of TOP-REAL n by A2;
A4: p in P by A3;
  set P2 = R \ P;
  reconsider P22=P2 as Subset of TOP-REAL n;
A5: [#]((TOP-REAL n) | R) = R by PRE_TOPC:def 5;
  then reconsider P11 = P, P12 = P22 as Subset of (TOP-REAL n) | R by A2,A3
,Th61,XBOOLE_1:36;
  reconsider P11, P12 as Subset of (TOP-REAL n) | R;
  P \/ (R \ P) = P \/ R by XBOOLE_1:39;
  then
A6: P11 misses P12 & [#]((TOP-REAL n) | R) = P11 \/ P12 by A5,XBOOLE_1:12,79;
  now
    let x be object;
A7: now
      assume
A8:   x in P2;
      then reconsider q2=x as Point of TOP-REAL n;
      not x in P by A8,XBOOLE_0:def 5;
      then
A9:   q2<>p & not ex f being Function of I[01],TOP-REAL n st f is
      continuous & rng f c= R & f.0=p & f.1=q2 by A3;
      q2 in R by A8,XBOOLE_0:def 5;
      hence x in {q: q<>p & q in R & not ex f being Function of I[01],TOP-REAL
      n st f is continuous & rng f c= R & f.0=p & f.1=q} by A9;
    end;
    now
      assume x in {q: q<>p & q in R & not ex f being Function of I[01],
      TOP-REAL n st f is continuous & rng f c= R & f.0=p & f.1=q};
      then
A10:  ex q3 st q3=x & q3<>p & q3 in R & not ex f being Function of I[01],
      TOP-REAL n st f is continuous & rng f c= R & f.0=p & f.1=q3;
      then not ex q st q=x & (q=p or ex f being Function of I[01],TOP-REAL n
      st f is continuous & rng f c= R & f.0=p & f.1=q);
      then not x in P by A3;
      hence x in P2 by A10,XBOOLE_0:def 5;
    end;
    hence
    x in P2 iff x in {q: q<>p & q in R & not ex f being Function of I[01]
    ,TOP-REAL n st f is continuous & rng f c= R & f.0=p & f.1=q} by A7;
  end;
  then
  P2={q: q<>p & q in R & not ex f being Function of I[01],TOP-REAL n st f
  is continuous & rng f c= R & f.0=p & f.1=q} by TARSKI:2;
  then P22 is open by A1,Th59;
  then
A11: P22 in the topology of TOP-REAL n by PRE_TOPC:def 2;
  reconsider PPP=P as Subset of TOP-REAL n;
  PPP is open by A1,A2,A3,Th60;
  then
A12: P in the topology of TOP-REAL n by PRE_TOPC:def 2;
  P11 = P /\ [#]((TOP-REAL n) | R) by XBOOLE_1:28;
  then P11 in the topology of (TOP-REAL n) | R by A12,PRE_TOPC:def 4;
  then
A13: P11 is open by PRE_TOPC:def 2;
  P12 = P22 /\ [#]((TOP-REAL n) | R) by XBOOLE_1:28;
  then P12 in the topology of ( TOP-REAL n) | R by A11,PRE_TOPC:def 4;
  then
A14: P12 is open by PRE_TOPC:def 2;
  (TOP-REAL n) | R9 is connected by A1,CONNSP_1:def 3;
  then P11 = {}((TOP-REAL n) | R) or P12 = {}((TOP-REAL n) | R) by A6,A13,A14,
CONNSP_1:11;
  hence thesis by A4,XBOOLE_1:37;
end;
