reserve x,O for set,
  o for Element of O,
  G,H,I for GroupWithOperators of O,
  A, B for Subset of G,
  N for normal StableSubgroup of G,
  H1,H2,H3 for StableSubgroup of G,
  g1,g2 for Element of G,
  h1,h2 for Element of H1,
  h for Homomorphism of G,H;
reserve E for set,
  A for Action of O,E,
  C for Subset of G,
  N1 for normal StableSubgroup of H1;

theorem Th79:
  for G,H being GroupWithOperators of O, N being StableSubgroup of
G, G9 being strict StableSubgroup of G, f being Homomorphism of G,H st N = Ker
  f holds ex H9 being strict StableSubgroup of H st the carrier of H9 = f.:(the
carrier of G9) & f"(the carrier of H9) = the carrier of G9"\/"N & (f is onto &
  G9 is normal implies H9 is normal)
proof
  let G,H be GroupWithOperators of O;
  let N be StableSubgroup of G;
  reconsider N9=the multMagma of N as strict Subgroup of G by Lm15;
  let G9 be strict StableSubgroup of G;
  reconsider G99 = the multMagma of G9 as strict Subgroup of G by Lm15;
  let f be Homomorphism of G,H;
  set A = {f.g where g is Element of G:g in G99};
A1: G99*N9 = G9*N & N9*G99 = N*G9;
  1_G in G99 by GROUP_2:46;
  then f.(1_G) in A;
  then reconsider A as non empty set;
  now
    let x be object;
    assume x in A;
    then ex g be Element of G st x=f.g & g in G99;
    hence x in the carrier of H;
  end;
  then reconsider A as Subset of H by TARSKI:def 3;
A2: now
    let h1,h2 be Element of H;
    assume that
A3: h1 in A and
A4: h2 in A;
    consider a be Element of G such that
A5: h1=f.a & a in G99 by A3;
    consider b be Element of G such that
A6: h2=f.b & b in G99 by A4;
    f.(a*b) = h1*h2 & a*b in G99 by A5,A6,GROUP_2:50,GROUP_6:def 6;
    hence h1*h2 in A;
  end;
A7: now
    let o be Element of O;
    let h be Element of H;
    assume h in A;
    then consider g be Element of G such that
A8: h=f.g and
A9: g in G99;
    g in the carrier of G99 by A9,STRUCT_0:def 5;
    then g in G9 by STRUCT_0:def 5;
    then (G^o).g in G9 by Lm9;
    then (G^o).g in the carrier of G9 by STRUCT_0:def 5;
    then
A10: (G^o).g in G99 by STRUCT_0:def 5;
    (H^o).h = f.((G^o).g) by A8,Def18;
    hence (H^o).h in A by A10;
  end;
  now
    let h be Element of H;
    assume h in A;
    then consider g be Element of G such that
A11: h=f.g & g in G99;
    g" in G99 & h"=f.(g") by A11,Lm13,GROUP_2:51;
    hence h" in A;
  end;
  then consider H99 be strict StableSubgroup of H such that
A12: the carrier of H99 = A by A2,A7,Lm14;
  assume
A13: N = Ker f;
  then N9 is normal by Def10;
  then
A14: carr G99 * N9 = N9 * carr G99 by GROUP_3:120;
  reconsider H9 = the multMagma of H99 as strict Subgroup of H by Lm15;
  take H99;
A15: now
    reconsider R = f as Relation of the carrier of G, the carrier of H;
    let h be Element of H;
    hereby
      assume h in A;
      then consider g be Element of G such that
A16:  h=f.g and
A17:  g in G99;
A18:  g in the carrier of G9 by A17,STRUCT_0:def 5;
      dom f = the carrier of G by FUNCT_2:def 1;
      then [g,h] in f by A16,FUNCT_1:1;
      hence h in f.:(the carrier of G9) by A18,RELSET_1:29;
    end;
    assume h in f.:(the carrier of G9);
    then consider g be Element of G such that
A19: [g,h] in R & g in the carrier of G9 by RELSET_1:29;
    f.g=h & g in G99 by A19,FUNCT_1:1,STRUCT_0:def 5;
    hence h in A;
  end;
  hence
A20: the carrier of H99 = f.:(the carrier of G9) by A12,SUBSET_1:3;
A21: now
    let x be object;
    assume
A22: x in f"(the carrier of H9);
    then f.x in the carrier of H9 by FUNCT_1:def 7;
    then consider g1 be object such that
A23: g1 in dom f and
A24: g1 in the carrier of G9 and
A25: f.g1 = f.x by A20,FUNCT_1:def 6;
    reconsider g1,g2=x as Element of G by A22,A23;
    consider g3 be Element of G such that
A26: g2 = g1 * g3 by GROUP_1:15;
    f.g2 = f.g2*f.g3 by A25,A26,GROUP_6:def 6;
    then f.g3 = 1_H by GROUP_1:7;
    then g3 in Ker f by Th47;
    then g3 in the carrier of N by A13,STRUCT_0:def 5;
    hence x in G99 * N9 by A24,A26;
  end;
A27: dom f = the carrier of G by FUNCT_2:def 1;
  now
    let x be object;
    assume
A28: x in G99 * N9;
    then consider g1,g2 be Element of G such that
A29: x = g1*g2 and
A30: g1 in carr G9 and
A31: g2 in carr N9;
A32: g2 in Ker f by A13,A31,STRUCT_0:def 5;
    f.x = f.g1*f.g2 by A29,GROUP_6:def 6
      .= f.g1*1_H by A32,Th47
      .= f.g1 by GROUP_1:def 4;
    then f.x in f.:(the carrier of G9) by A27,A30,FUNCT_1:def 6;
    then x in f"(f.:(the carrier of G9)) by A27,A28,FUNCT_1:def 7;
    hence x in f"(the carrier of H9) by A12,A15,SUBSET_1:3;
  end;
  then f"(the carrier of H9) = carr G9 * carr N by A21,TARSKI:2;
  hence f"(the carrier of H99) = the carrier of G9"\/"N by A14,A1,Th30;
  now
    assume that
A33: f is onto and
A34: G9 is normal;
A35: G99 is normal by A34;
    now
      let h1 be Element of H;
      now
        let x be object;
        assume x in h1 * H9;
        then consider h2 be Element of H such that
A36:    x=h1*h2 and
A37:    h2 in A by A12,GROUP_2:27;
        set h29 = h1*h2*h1";
        h2 in f.:(the carrier of G9) by A15,A37;
        then consider g2 be object such that
A38:    g2 in dom f and
A39:    g2 in the carrier of G99 and
A40:    f.g2 = h2 by FUNCT_1:def 6;
        rng f = the carrier of H by A33;
        then consider g1 be object such that
A41:    g1 in dom f and
A42:    h1 = f.g1 by FUNCT_1:def 3;
        reconsider g1,g2 as Element of G by A38,A41;
        set g29=g1*g2*g1";
        g29=(g1"")*g2*g1";
        then
A43:    g29=g2 |^ g1" by GROUP_3:def 2;
        g2 in G99 by A39,STRUCT_0:def 5;
        then g29 in G99 |^ g1" by A43,GROUP_3:58;
        then
A44:    g29 in the carrier of G99 |^ g1" by STRUCT_0:def 5;
        G99 |^ g1" is Subgroup of G99 by A35,GROUP_3:122;
        then
A45:    the carrier of G99 |^ g1" c= the carrier of G99 by GROUP_2:def 5;
        h29 = f.g1*f.g2*f.(g1") by A40,A42,Lm13
          .= f.(g1*g2)*f.(g1") by GROUP_6:def 6
          .= f.g29 by GROUP_6:def 6;
        then h29 in f.:(the carrier of G99) by A27,A44,A45,FUNCT_1:def 6;
        then
A46:    h29 in A by A15;
        h29*h1 = (h1*h2)*(h1"*h1) by GROUP_1:def 3
          .= (h1*h2)*1_H by GROUP_1:def 5
          .= x by A36,GROUP_1:def 4;
        hence x in H9 * h1 by A12,A46,GROUP_2:28;
      end;
      hence h1 * H9 c= H9 * h1;
    end;
    then for H1 being strict Subgroup of H st H1 = the multMagma of H99 holds
    H1 is normal by GROUP_3:118;
    hence H99 is normal;
  end;
  hence thesis;
end;
