reserve m,n,i,i2,j for Nat,
  r,r1,r2,s,t for Real,
  x,y,z for object;
reserve p,p1,p2,p3,q,q1,q2,q3,q4 for Point of TOP-REAL n;
reserve u for Point of Euclid n;
reserve R for Subset of TOP-REAL n;
reserve P,Q for Subset of TOP-REAL n;

theorem Th63:
  for R being Subset of TOP-REAL n, p,q being Point of TOP-REAL n
  st R is connected & R is open & p in R & q in R & p<>q holds ex f being
  Function of I[01],TOP-REAL n st f is continuous & rng f c= R & f.0=p & f.1=q
proof
  let R be Subset of TOP-REAL n, p,q be Point of TOP-REAL n;
  assume that
A1: R is connected & R is open & p in R and
A2: q in R and
A3: p<>q;
  set RR={q2: q2=p or ex f being Function of I[01],TOP-REAL n st f is
  continuous & rng f c= R & f.0=p & f.1=q2};
  RR c= the carrier of TOP-REAL n
  proof
    let x be object;
    assume x in RR;
    then
    ex q2 st q2=x & (q2=p or ex f being Function of I[01],TOP-REAL n st f
    is continuous & rng f c= R & f.0=p & f.1=q2);
    hence thesis;
  end;
  then R c= RR by A1,Th62;
  then q in RR by A2;
  then
  ex q2 st q=q2 &(q2=p or ex f being Function of I[01],TOP-REAL n st f is
  continuous & rng f c= R & f.0=p & f.1=q2);
  hence thesis by A3;
end;
