
theorem Th92:
  for a being Ordinal holds a is limit_ordinal
    iff not 0 in rng(omega -exponent CantorNF a)
proof
  let a be Ordinal;
  per cases;
  suppose a = 0;
    hence thesis by ORDINAL2:4;
  end;
  suppose a <> 0;
    then consider A0 being Cantor-normal-form Ordinal-Sequence,
      a0 be Cantor-component Ordinal such that
      A2: CantorNF a = A0 ^ <% a0 %> by Th29;
    hereby
      assume A3: a is limit_ordinal;
      omega -exponent last CantorNF a <> 0
      proof
        assume omega -exponent last CantorNF a = 0;
        then omega -exponent a0 = 0 by A2, AFINSQ_1:92;
        then a0
           = (omega -leading_coeff a0) *^ exp(omega, 0 qua Ordinal) by Th59
          .= (omega -leading_coeff a0) *^ 1 by ORDINAL2:43
          .= omega -leading_coeff a0 by ORDINAL2:39;
        then A6: Sum^ CantorNF a = Sum^ A0 +^ omega -leading_coeff a0
          by A2, ORDINAL5:54;
        then A7: Sum^ A0 c= a by ORDINAL3:24;
        Sum^ A0 <> a
        proof
          assume Sum^ A0 = a;
          then Sum^ A0 +^ 0 = Sum^ A0 +^ omega -leading_coeff a0
            by A6, ORDINAL2:27;
          hence contradiction by ORDINAL3:21;
        end;
        then Sum^ A0 in a by A7, XBOOLE_0:def 8, ORDINAL1:11;
        then Sum^ A0 +^ omega -leading_coeff a0 in a by A3, CARD_2:70;
        hence contradiction by A6;
      end;
      hence not 0 in rng(omega -exponent CantorNF a) by Th51;
    end;
    assume A8: not 0 in rng(omega -exponent CantorNF a);
    now
      let b be Ordinal;
      assume b in a;
      then A9: succ b in succ a by ORDINAL3:3;
      not succ b = a
      proof
        assume succ b = a;
        then A10: a = b (+) 1 by Th90;
        set E1 = omega -exponent CantorNF b, E2 = omega -exponent CantorNF 1;
        set L1 = omega -leading_coeff CantorNF b;
        set L2 = omega -leading_coeff CantorNF 1;
        consider C being Cantor-normal-form Ordinal-Sequence such that
          A11: b (+) 1 = Sum^ C & rng(omega -exponent C) = rng E1 \/ rng E2 and
          for d being object st d in dom C holds
            (omega -exponent(C.d) in rng E1 \ rng E2 implies
              omega -leading_coeff(C.d) = L1.(E1".(omega -exponent(C.d)))) &
            (omega -exponent(C.d) in rng E2 \ rng E1 implies
              omega -leading_coeff(C.d) = L2.(E2".(omega -exponent(C.d)))) &
            (omega -exponent(C.d) in rng E1 /\ rng E2 implies
              omega -leading_coeff(C.d) = L1.(E1".(omega -exponent(C.d))) +
                L2.(E2".(omega -exponent(C.d)))) by Def5;
        E2 = omega -exponent <% 1 %> by Th71
          .= <% omega -exponent 1 %> by Th46
          .= <% 0 %> by Th21;
        then rng E2 = {0} by AFINSQ_1:33;
        then 0 in rng E2 by TARSKI:def 1;
        hence contradiction by A8, A10, A11, XBOOLE_1:7, TARSKI:def 3;
      end;
      hence succ b in a by A9, ORDINAL1:8;
    end;
    hence thesis by ORDINAL1:28;
  end;
end;
