reserve X,Y for set, x,y,z for object, i,j,n for natural number;

theorem
  for S being non empty non void ManySortedSign
  for o being OperSymbol of S, s1,s2,s3,r being SortSymbol of S,
      T being MSAlgebra over S holds
  o is_of_type <*s1,s2,s3*>,r & x in (the Sorts of T).s1 &
  y in (the Sorts of T).s2 & z in (the Sorts of T).s3
  implies <*x,y,z*> in Args(o,T)
  proof
    let S be non empty non void ManySortedSign;
    let o be OperSymbol of S;
    let s1,s2,s3,r be SortSymbol of S;
    let A be MSAlgebra over S;
    assume A1: (the Arity of S).o = <*s1,s2,s3*> & (the ResultSort of S).o = r;
    assume A2: x in (the Sorts of A).s1 & y in (the Sorts of A).s2 &
    z in (the Sorts of A).s3;
A3: the Sorts of A is Function of the carrier of S, bool Union the Sorts of A
    by Lm1;
    Args(o,A) = product ((the Sorts of A)*the_arity_of o) by PRALG_2:3
    .= product <*(the Sorts of A).s1,(the Sorts of A).s2,(the Sorts of A).s3*>
    by A1,A3,FINSEQ_2:37;
    hence <*x,y,z*> in Args(o,A) by A2,FINSEQ_3:125;
  end;
