reserve D,D1,D2 for non empty set,
        d,d1,d2 for XFinSequence of D,
        n,k,i,j for Nat;

theorem Th7:
  for f,g be Function st f is one-to-one
     for x be object st x in dom f holds Coim(f*g,f.x) = Coim(g,x)
proof
  let f,g be Function such that
A1: f is one-to-one;
  let x be object such that
A2: x in dom f;
  set fg=f*g;
  thus Coim(fg,f.x) c= Coim(g,x)
  proof
    let z be object;
    assume
A3:   z in Coim(fg,f.x);
    then
A4: z in dom fg by FUNCT_1:def 7;
A5: fg.z in {f.x} by A3,FUNCT_1:def 7;
A6: z in dom g by A4,FUNCT_1:11;
A7: g.z in dom f by A4,FUNCT_1:11;
A8: fg.z=f.(g.z) by A4,FUNCT_1:12;
    fg.z=f.x by A5,TARSKI:def 1;
    then g.z=x by A7,A8,A2,A1;
    then g.z in {x} by TARSKI:def 1;
    hence thesis by FUNCT_1:def 7,A6;
  end;
  let z be object;
  assume
A9: z in Coim(g,x);
  then
A10: z in dom g by FUNCT_1:def 7;
  g.z in {x} by A9,FUNCT_1:def 7;
  then
A11: g.z=x by TARSKI:def 1;
  then
A12:  fg.z=f.x by FUNCT_1:13,A10;
A13:  z in dom fg by A11,A2,FUNCT_1:11,A10;
  f.x in {f.x} by TARSKI:def 1;
  hence thesis by A12,A13,FUNCT_1:def 7;
end;
