reserve Omega for non empty set,
        Sigma for SigmaField of Omega,
        Prob for Probability of Sigma,
        A for SetSequence of Sigma,
        n,n1,n2 for Nat;

theorem Th7:
  (Partial_Intersection Complement A).n = ((Partial_Union A).n)`
proof
for x being object holds
(x in (Partial_Intersection Complement A).n iff
 x in ((Partial_Union A).n)`)
proof
let x be object;
hereby assume A1: x in (Partial_Intersection (Complement A)).n;
   for knat being Nat st knat<=n holds not x in A.knat
   proof
    let knat be Nat;
    assume knat<=n; then
    A2: x in (Complement A).knat by A1,PROB_3:25;
    reconsider knat as Element of NAT by ORDINAL1:def 12;
    (Complement A).knat=(A.knat)` by PROB_1:def 2; then
    (Complement A).knat=Omega \ A.knat by SUBSET_1:def 4;
    hence thesis by A2,XBOOLE_0:def 5;
   end; then
   A3: not x in (Partial_Union A).n by PROB_3:26;
   x in Omega \ (Partial_Union A).n by A1,A3,XBOOLE_0:def 5;
   hence x in ((Partial_Union A).n)` by SUBSET_1:def 4;
  end;
assume A4: x in ((Partial_Union A).n)`;
   x in Omega \ (Partial_Union A).n by A4,SUBSET_1:def 4; then
   A5: x in Omega & not x in (Partial_Union A).n by XBOOLE_0:def 5;
   for knat being Nat st knat<=n holds x in (Complement A).knat
   proof
    let knat be Nat;
    assume knat<=n; then
    x in Omega & not x in A.knat by A5,PROB_3:26; then
    A6: x in Omega \ A.knat by XBOOLE_0:def 5;
    reconsider knat as Element of NAT by ORDINAL1:def 12;
    x in (A.knat)` by A6,SUBSET_1:def 4;
    hence thesis by PROB_1:def 2;
   end;
   hence x in (Partial_Intersection (Complement A)).n by PROB_3:25;
end;
hence thesis by TARSKI:2;
end;
