reserve i, x, I for set,
  A, M for ManySortedSet of I,
  f for Function,
  F for ManySortedFunction of I;

theorem Th7: :: FUNCT_2:18
  for A, B being non-empty ManySortedSet of I for F, G being
  ManySortedFunction of A, B st for M st M in A holds F..M = G..M holds F = G
proof
  let A, B be non-empty ManySortedSet of I, F, G be ManySortedFunction of A, B
  such that
A1: for M st M in A holds F..M = G..M;
  now
    let i be object;
    assume
A2: i in I;
    then reconsider f = F.i as Function of A.i, B.i by PBOOLE:def 15;
    reconsider g = G.i as Function of A.i, B.i by A2,PBOOLE:def 15;
    now
      consider K being ManySortedSet of I such that
A4:   K in A by PBOOLE:134;
      let x be object such that
A5:   x in A.i;
      dom (K +* (i .--> x)) = I by A2,PZFMISC1:1;
      then reconsider X = K +* (i .--> x) as ManySortedSet of I by
PARTFUN1:def 2,RELAT_1:def 18;
A6:   dom (i .--> x) = {i};
      i in {i} by TARSKI:def 1;
      then
A7:   X.i = (i .--> x).i by A6,FUNCT_4:13
        .= x by FUNCOP_1:72;
      X in A
      proof
        let s be object such that
A8:     s in I;
        per cases;
        suppose
          s = i;
          hence thesis by A5,A7;
        end;
        suppose
          s <> i;
          then not s in dom (i .--> x) by TARSKI:def 1;
          then X.s = K.s by FUNCT_4:11;
          hence thesis by A4,A8;
        end;
      end;
      then
A9:   F..X = G..X by A1;
      thus f.x = (F..X).i by A2,A7,PRALG_1:def 20
        .= g.x by A2,A7,A9,PRALG_1:def 20;
    end;
    hence F.i = G.i by FUNCT_2:12;
  end;
  hence thesis;
end;
