
theorem Th7:
  for C being FormalContext for O being Subset of the carrier of C
holds (ObjectDerivation(C)).O = (ObjectDerivation(C)).((AttributeDerivation(C))
  .((ObjectDerivation(C)).O))
proof
  let C be FormalContext;
  let O be Subset of the carrier of C;
  set A = {a where a is Attribute of C : for o being Object of C st o in O
  holds o is-connected-with a};
  set O9 = {o where o is Object of C : for a being Attribute of C st a in A
  holds o is-connected-with a};
  set A9 = {a where a is Attribute of C : for o being Object of C st o in O9
  holds o is-connected-with a};
A1: for x being object holds x in A9 implies x in A
  proof
    let x be object;
    assume x in A9;
    then
A2: ex x9 being Attribute of C st x9 = x & for o being Object of C st o in
    O9 holds o is-connected-with x9;
    then reconsider x as Attribute of C;
    for o being Object of C st o in O holds o is-connected-with x
    proof
      let o be Object of C;
      assume
A3:   o in O;
      now
        per cases;
        case
          o in O9;
          hence thesis by A2;
        end;
        case
          not o in O9;
          then consider a being Attribute of C such that
A4:       a in A and
A5:       not o is-connected-with a;
          ex a9 being Attribute of C st a9 = a & for o being Object of C
          st o in O holds o is-connected-with a9 by A4;
          hence thesis by A3,A5;
        end;
      end;
      hence thesis;
    end;
    hence thesis;
  end;
  for x being object holds x in A implies x in A9
  proof
    let x be object;
    assume
A6: x in A;
    then
    ex x9 being Attribute of C st x9 = x & for o being Object of C st o in
    O holds o is-connected-with x9;
    then reconsider x as Attribute of C;
    for o being Object of C st o in O9 holds o is-connected-with x
    proof
      let o be Object of C;
      assume o in O9;
      then ex o9 being Object of C st o9 = o & for a being Attribute of C st a
      in A holds o9 is-connected-with a;
      hence thesis by A6;
    end;
    hence thesis;
  end;
  then
A7: A = A9 by A1,TARSKI:2;
  A c= the carrier' of C
  proof
    let x be object;
    assume x in A;
    then
    ex x9 being Attribute of C st x9 = x & for o being Object of C st o in
    O holds o is-connected-with x9;
    hence thesis;
  end;
  then reconsider A as Subset of the carrier' of C;
  O9 c= the carrier of C
  proof
    let x be object;
    assume x in O9;
    then
    ex x9 being Object of C st x9 = x & for a being Attribute of C st a in
    A holds x9 is-connected-with a;
    hence thesis;
  end;
  then reconsider O9 as Subset of the carrier of C;
  A = (ObjectDerivation(C)).O & O9 = (AttributeDerivation(C)).A by Def2,Def3;
  hence thesis by A7,Def2;
end;
