
theorem Th7:
  for X be non empty set for Y be ComplexNormSpace holds
  ComplexBoundedFunctions(X,Y) is linearly-closed
proof
  let X be non empty set;
  let Y be ComplexNormSpace;
  set W = ComplexBoundedFunctions(X,Y);
A1: for v,u be VECTOR of ComplexVectSpace(X,Y) st v in W & u in W holds v +
  u in W
  proof
    let v,u be VECTOR of ComplexVectSpace(X,Y) such that
A2: v in W and
A3: u in W;
    reconsider f=v+u as Function of X,the carrier of Y by FUNCT_2:66;
    f is bounded
    proof
      reconsider v1=v as bounded Function of X, the carrier of Y by A2,Def5;
      consider K2 be Real such that
A4:   0 <= K2 and
A5:   for x be Element of X holds ||. v1.x .|| <= K2 by Def4;
      reconsider u1=u as bounded Function of X, the carrier of Y by A3,Def5;
      consider K1 be Real such that
A6:   0 <= K1 and
A7:   for x be Element of X holds ||. u1.x .|| <= K1 by Def4;
      take K3=K1+K2;
      now
        let x be Element of X;
        ||. u1.x .|| <= K1 & ||. v1.x .|| <= K2 by A7,A5;
        then
A8:     ||. u1.x .|| + ||. v1.x .|| <= K1 +K2 by XREAL_1:7;
        ||. f.x .|| =||. v1.x+u1.x .|| & ||. u1.x+v1.x .|| <= ||. u1.x
        .||+ ||. v1.x .|| by CLOPBAN1:11,CLVECT_1:def 13;
        hence ||. f.x .|| <= K3 by A8,XXREAL_0:2;
      end;
      hence thesis by A6,A4;
    end;
    hence thesis by Def5;
  end;
  for c be Complex for v be VECTOR of ComplexVectSpace(X,Y) st v in W
  holds c * v in W
  proof
    let c be Complex;
    let v be VECTOR of ComplexVectSpace(X,Y) such that
A9: v in W;
    reconsider f=c*v as Function of X,the carrier of Y by FUNCT_2:66;
    f is bounded
    proof
      reconsider v1=v as bounded Function of X, the carrier of Y by A9,Def5;
      consider K be Real such that
A10:  0 <= K and
A11:  for x be Element of X holds ||. v1.x .|| <= K by Def4;
      take |.c.|*K;
A12:  now
        let x be Element of X;
A13:    0 <=|.c.| by COMPLEX1:46;
        ||. f.x .|| =||. c*v1.x .|| & ||. c*v1.x .|| = |.c.|* ||. v1.x
        .|| by CLOPBAN1:12,CLVECT_1:def 13;
        hence ||. f.x .|| <= |.c.|* K by A11,A13,XREAL_1:64;
      end;
      0 <=|.c.| by COMPLEX1:46;
      hence thesis by A10,A12;
    end;
    hence thesis by Def5;
  end;
  hence thesis by A1,CLVECT_1:def 7;
end;
