reserve Rseq, Rseq1, Rseq2 for Function of [:NAT,NAT:],REAL;
reserve rseq1,rseq2 for convergent Real_Sequence;
reserve n,m,N,M for Nat;
reserve e,r for Real;
reserve Pseq for P-convergent Function of [:NAT,NAT:],REAL;

theorem
Rseq is P-convergent iff Rseq is Cauchy
proof
   hereby assume a1: Rseq is P-convergent;
    now let e;
     assume a2: e > 0;
     consider z be Real such that
a3:   for e st 0<e
       ex N st
        for n,m st n>=N & m>=N holds |.Rseq.(n,m) - z.| < e by a1;
     consider N such that
a4:   for n,m st n>=N & m>=N holds |.Rseq.(n,m) - z.| < e/2 by a2,a3;
     now let n1,n2,m1,m2 be Nat;
      assume b1: N<=n1 & n1<=n2 & N<=m1 & m1<=m2; then
      N<=n2 & N<=m2 by XXREAL_0:2; then
      |.Rseq.(n1,m1) - z.| < e/2 & |.Rseq.(n2,m2) - z.| < e/2 by a4,b1; then
      |.Rseq.(n2,m2) - z.| + |.Rseq.(n1,m1) - z.| < e/2 + e/2
        by XREAL_1:8; then
a5:   |.Rseq.(n2,m2) - z.| + |.z - Rseq.(n1,m1).| < e by COMPLEX1:60;
      |.Rseq.(n2,m2) - Rseq.(n1,m1).|
       <= |.Rseq.(n2,m2) - z.| + |.z - Rseq.(n1,m1).| by COMPLEX1:63;
      hence |.Rseq.(n2,m2) - Rseq.(n1,m1).| < e by a5,XXREAL_0:2;
     end;
     hence ex N st
      for n1,n2,m1,m2 be Nat st N<=n1 & n1<=n2 & N<=m1 & m1<=m2
       holds |.Rseq.(n2,m2) - Rseq.(n1,m1).| < e;
    end;
    hence Rseq is Cauchy;
   end;
   assume a6: Rseq is Cauchy;
   deffunc F(Element of NAT) = Rseq.($1,$1);
   consider seq be Function of NAT,REAL such that
a7: for n be Element of NAT holds seq.n = F(n) from FUNCT_2:sch 4;
   reconsider seq as Real_Sequence;
   now let e;
    assume e > 0; then
    consider N such that
a8:  for n1,n2,m1,m2 be Nat st N<=n1 & n1<=n2 & N<=m1 & m1<=m2
      holds |. Rseq.(n2,m2) - Rseq.(n1,m1).| < e by a6;
    take N;
    hereby let n;
c1:  n is Element of NAT & N is Element of NAT by ORDINAL1:def 12;
     assume n>=N; then
     |. Rseq.(n,n) - Rseq.(N,N).| < e by a8; then
     |. seq.n - Rseq.(N,N).| < e by a7,c1;
     hence |. seq.n - seq.N .| < e by a7,c1;
    end;
   end; then
a11:   seq is convergent by SEQ_4:41;
   reconsider z = lim seq as Complex;
   for e st 0<e
    ex N st for n,m st n>=N & m>=N holds |.Rseq.(n,m) - z.| < e
   proof
    let e;
    assume a12: 0<e; then
    consider N1 be Nat such that
a13: for n st n>=N1 holds |. seq.n - lim seq.| < e/2 by a11,SEQ_2:def 7;
    consider N2 be Nat such that
a14: for n1,n2,m1,m2 be Nat st N2<=n1 & n1<=n2 & N2<=m1 & m1<=m2
       holds |. Rseq.(n2,m2) - Rseq.(n1,m1).| < e/2 by a6,a12;
    reconsider N = max(N1,N2) as Nat by TARSKI:1;
    take N;
    hereby let n,m;
c2:  N is Element of NAT by ORDINAL1:def 12;
     assume a15: n>=N & m>=N;
a18: Rseq.(N,N) = seq.N by a7,c2;
     N>=N1 & N>=N2 by XXREAL_0:25; then
     |. Rseq.(N,N) - z.| < e/2 & |. Rseq.(n,m) - Rseq.(N,N).| < e/2
       by a13,a14,a18,a15; then
b1:  |. Rseq.(n,m) - Rseq.(N,N).| + |. Rseq.(N,N) - z.| < e/2+e/2
       by XREAL_1:8;
     |. Rseq.(n,m) - z.| <= |. Rseq.(n,m) - Rseq.(N,N).| + |. Rseq.(N,N) - z.|
       by COMPLEX1:63;
     hence |. Rseq.(n,m) - z.| < e by b1,XXREAL_0:2;
    end;
   end;
   hence Rseq is P-convergent;
end;
