
theorem Th6:
  for L being non empty transitive antisymmetric RelStr,
  x being Element of L, a, N being set
  st a is_minimal_wrt (the InternalRel of L)-Seg(x) /\ N,(the InternalRel of L)
  holds a is_minimal_wrt N, (the InternalRel of L)
proof
  let L be non empty transitive antisymmetric RelStr,
  x be Element of L, a,N be set such that
  A1: a
 is_minimal_wrt (the InternalRel of L)-Seg(x) /\ N,(the InternalRel of L);
  set IR = the InternalRel of L, CR = the carrier of L;
A2: IR is_transitive_in CR by ORDERS_2:def 3;
  now
A3: a in IR-Seg(x) /\ N by A1,WAYBEL_4:def 25;
    then
A4: a in IR-Seg(x) by XBOOLE_0:def 4;
    then
A5: a <> x by WELLORD1:1;
A6: [a,x] in IR by A4,WELLORD1:1;
    then reconsider a9 = a as Element of L by ZFMISC_1:87;
    thus a in N by A3,XBOOLE_0:def 4;
    now
      assume ex y being set st y in N & y <> a & [y,a] in IR;
      then consider y being set such that
A7:   y in N and
A8:   y <> a and
A9:   [y,a] in IR;
A10:  a in CR by A9,ZFMISC_1:87;
      y in CR by A9,ZFMISC_1:87;
      then
A11:  [y,x] in IR by A2,A6,A9,A10;
      per cases;
      suppose x = y;
        then
A12:    x <= a9 by A9;
        a9 <= x by A6;
        hence contradiction by A5,A12,ORDERS_2:2;
      end;
      suppose x <> y;
        then y in IR-Seg(x) by A11,WELLORD1:1;
        then y in IR-Seg(x) /\ N by A7,XBOOLE_0:def 4;
        hence contradiction by A1,A8,A9,WAYBEL_4:def 25;
      end;
    end;
    hence not ex y being set st y in N & y <> a & [y,a] in IR;
  end;
  hence thesis by WAYBEL_4:def 25;
end;
