reserve x,y for set,
  n for Nat;

theorem Th7:
  for f be with_zero non empty FinSequence of NAT, D be
  disjoint_with_NAT set holds signature (FreeUnivAlgZAO(f,D)) = f
proof
  let f be with_zero non empty FinSequence of NAT, D be disjoint_with_NAT set;
  set fa = FreeUnivAlgZAO(f,D), A = TS DTConUA(f,D);
A1: len the charact of fa = len f by Def17;
A2: len(signature fa) = len the charact of(fa) by UNIALG_1:def 4;
  then
A3: dom(signature fa) = Seg len f by A1,FINSEQ_1:def 3;
  now
    let n be Nat;
    reconsider h = FreeOpZAO(n,f,D) as homogeneous quasi_total non empty
    PartFunc of (the carrier of fa)*,(the carrier of fa);
A4: dom h = (arity h)-tuples_on (the carrier of fa) by MARGREL1:22;
    assume
A5: n in dom(signature fa);
    then
A6: n in dom f by A3,FINSEQ_1:def 3;
    then dom h = (f/.n)-tuples_on A by Def16;
    then
A7: arity h = f/.n by A4,FINSEQ_2:110;
    n in dom(FreeOpSeqZAO(f,D)) by A1,A3,A5,FINSEQ_1:def 3;
    then (the charact of fa).n = FreeOpZAO(n,f,D) by Def17;
    hence (signature fa).n = arity h by A5,UNIALG_1:def 4
      .= f.n by A6,A7,PARTFUN1:def 6;
  end;
  hence thesis by A2,A1,FINSEQ_2:9;
end;
