reserve p, q for FinSequence,
  e,X for set,
  i, j, k, m, n for Nat,
  G for Graph;
reserve x,y,v,v1,v2,v3,v4 for Element of G;
reserve vs, vs1, vs2 for FinSequence of the carrier of G,
  c, c1, c2 for oriented Chain of G;

theorem
  c <>{} & vs is_oriented_vertex_seq_of c implies
  rng vs c= G-SVSet rng c \/ G-TVSet rng c
proof
  assume that
A1: c <>{} and
A2: vs is_oriented_vertex_seq_of c;
A3: len vs = len c + 1 by A2;
  let y be object;
  assume y in rng vs;
  then consider x being object such that
A4: x in dom vs and
A5: y = vs.x by FUNCT_1:def 3;
  reconsider x as Element of NAT by A4;
A6: 1<=x by A4,FINSEQ_3:25;
A7: x<=len vs by A4,FINSEQ_3:25;
  per cases by A3,A7,NAT_1:8;
  suppose
A8: x<=len c;
    then x in dom c by A6,FINSEQ_3:25;
    then
A9: c.x in rng c by FUNCT_1:def 3;
    rng c c= the carrier' of G by FINSEQ_1:def 4;
    then reconsider e = c.x as Element of the carrier' of G by A9;
    set v1 = vs/.x;
    set v2 = vs/.(x+1);
A10: v1 = vs.x by A6,A7,FINSEQ_4:15;
    c.x orientedly_joins v1, v2 by A2,A6,A8;
    then
A11: v1 = (the Source of G).e;
    x in dom c by A6,A8,FINSEQ_3:25;
    then e in rng c by FUNCT_1:def 3;
    then y in G-SVSet rng c by A5,A10,A11;
    hence thesis by XBOOLE_0:def 3;
  end;
  suppose
A12: x=len c+1;
    set l = len c;
    0+1=1;
    then
A13: 1<=l by A1,NAT_1:13;
    then l in dom c by FINSEQ_3:25;
    then
A14: c.l in rng c by FUNCT_1:def 3;
    rng c c= the carrier' of G by FINSEQ_1:def 4;
    then reconsider e = c.l as Element of the carrier' of G by A14;
    set v1 = vs/.l;
    set v2 = vs/.(l+1);
A15: v2 = vs.(l+1) by A3,A6,A12,FINSEQ_4:15;
    c.l orientedly_joins v1, v2 by A2,A13;
    then
A16: v2 = (the Target of G).e;
    l in dom c by A13,FINSEQ_3:25;
    then e in rng c by FUNCT_1:def 3;
    then y in G-TVSet rng c by A5,A12,A15,A16;
    hence thesis by XBOOLE_0:def 3;
  end;
end;
