reserve AFP for AffinPlane;
reserve a,a9,b,b9,c,c9,d,d9,o,p,p9,q,q9,r,s,t,x,y,z for Element of AFP;
reserve A,A9,C,D,P,B9,M,N,K for Subset of AFP;
reserve f for Permutation of the carrier of AFP;

theorem Th7:
  K // M & p in K & q in K & p9 in K & q9 in K & AFP is Moufangian
& a in M & b in M & x in M & y in M & a<>b & q<>p & p,a // p9,x & p,b // p9,y &
  q,a // q9,x implies q,b // q9,y
proof
  assume that
A1: K // M and
A2: p in K and
A3: q in K and
A4: p9 in K and
A5: q9 in K and
A6: AFP is Moufangian and
A7: a in M and
A8: b in M and
A9: x in M and
A10: y in M and
A11: a<>b and
A12: q<>p and
A13: p,a // p9,x and
A14: p,b // p9,y and
A15: q,a // q9,x;
A16: K is being_line by A1,AFF_1:36;
A17: M is being_line by A1,AFF_1:36;
  now
    set D9=Line(q9,x);
    set B99=Line(p9,y);
    set D=Line(q,a);
    set B9=Line(p,b);
A18: q in D by AFF_1:15;
A19: a in D by AFF_1:15;
A20: x in D9 by AFF_1:15;
A21: q9 in D9 by AFF_1:15;
A22: LIN p,q,q9 by A2,A3,A5,A16,AFF_1:21;
A23: LIN p,q,p9 by A2,A3,A4,A16,AFF_1:21;
    assume
A24: K<>M;
    then
A25: q9<>x by A1,A5,A9,AFF_1:45;
A26: not a in K by A1,A7,A24,AFF_1:45;
A27: b<>p by A1,A2,A8,A24,AFF_1:45;
    then
A28: B9 is being_line by AFF_1:def 3;
A29: not q in M by A1,A3,A24,AFF_1:45;
A30: not p in M by A1,A2,A24,AFF_1:45;
A31: LIN a,b,x by A7,A8,A9,A17,AFF_1:21;
A32: now
A33:  now
        assume that
A34:    q=p9 and
A35:    q=q9;
        LIN q,a,x by A15,A35,AFF_1:def 1;
        then LIN a,x,q by AFF_1:6;
        then a=x by A7,A9,A17,A29,AFF_1:25;
        then a,q // a,p by A13,A34,AFF_1:4;
        then LIN a,q,p by AFF_1:def 1;
        then LIN p,q,a by AFF_1:6;
        hence contradiction by A2,A3,A12,A16,A26,AFF_1:25;
      end;
A36:  now
        assume that
A37:    p=p9 and
A38:    p=q9;
        LIN p,a,x by A13,A37,AFF_1:def 1;
        then LIN a,x,p by AFF_1:6;
        then a=x by A7,A9,A17,A30,AFF_1:25;
        then a,q // a,q9 by A15,AFF_1:4;
        then LIN a,q,q9 by AFF_1:def 1;
        then LIN p,q,a by A38,AFF_1:6;
        hence contradiction by A2,A3,A12,A16,A26,AFF_1:25;
      end;
      assume
A39:  not ex a,b,c st LIN a,b,c & a<>b & a<>c & b<>c;
A40:  now
        assume that
A41:    q=p9 and
A42:    p=q9;
A43:    now
          assume
A44:      b=x;
          then q,y // q,a by A14,A15,A27,A41,A42,AFF_1:5;
          then LIN q,y,a by AFF_1:def 1;
          then LIN a,y,q by AFF_1:6;
          then q9,y // q,b by A7,A10,A13,A17,A29,A41,A42,A44,AFF_1:25;
          hence thesis by AFF_1:4;
        end;
        now
          assume a=x;
          then a,p // a,q by A13,A41,AFF_1:4;
          then LIN a,p,q by AFF_1:def 1;
          then LIN p,q,a by AFF_1:6;
          hence contradiction by A2,A3,A12,A16,A26,AFF_1:25;
        end;
        hence thesis by A11,A31,A39,A43;
      end;
      now
        assume that
A45:    p=p9 and
A46:    q=q9;
        LIN p,b,y by A14,A45,AFF_1:def 1;
        then LIN b,y,p by AFF_1:6;
        then b=y by A8,A10,A17,A30,AFF_1:25;
        hence thesis by A46,AFF_1:2;
      end;
      hence thesis by A12,A23,A22,A39,A36,A33,A40;
    end;
A47: y in B99 by AFF_1:15;
A48: p9 in B99 by AFF_1:15;
A49: b in B9 by AFF_1:15;
    then
A50: B9<>K by A1,A8,A24,AFF_1:45;
    a<>q by A1,A3,A7,A24,AFF_1:45;
    then
A51: D // D9 by A15,A25,AFF_1:37;
A52: p in B9 by AFF_1:15;
    then
A53: B9<>M by A1,A2,A24,AFF_1:45;
A54: p9<>y by A1,A4,A10,A24,AFF_1:45;
    then
A55: B9 // B99 by A14,A27,AFF_1:37;
A56: B99 is being_line by A54,AFF_1:def 3;
    now
A57:  a,q // x,q9 by A18,A19,A21,A20,A51,AFF_1:39;
      assume ex a,b,c st LIN a,b,c & a<>b & a<>c & b<>c;
      then consider d such that
A58:  LIN p,b,d and
A59:  d<>p and
A60:  d<>b by TRANSLAC:1;
      consider N such that
A61:  d in N and
A62:  K // N by A16,AFF_1:49;
A63:  d in B9 by A58,AFF_1:def 2;
      then
A64:  N<>M by A8,A17,A28,A49,A53,A60,A61,AFF_1:18;
A65:  not B99 // N
      proof
        assume B99 // N;
        then B9 // N by A55,AFF_1:44;
        then B9 // K by A62,AFF_1:44;
        hence contradiction by A2,A52,A50,AFF_1:45;
      end;
      N is being_line by A62,AFF_1:36;
      then consider z such that
A66:  z in B99 and
A67:  z in N by A56,A65,AFF_1:58;
A68:  d,b // z,y by A49,A47,A55,A63,A66,AFF_1:39;
A69:  N<>K by A2,A16,A28,A52,A50,A59,A63,A61,AFF_1:18;
A70:  M // N by A1,A62,AFF_1:44;
A71:  K<>N by A2,A16,A28,A52,A50,A59,A63,A61,AFF_1:18;
A72:  N // M by A1,A62,AFF_1:44;
      p,d // p9,z by A52,A48,A55,A63,A66,AFF_1:39;
      then
A73:  a,d // x,z by A1,A2,A4,A6,A7,A9,A13,A24,A61,A62,A67,A71,Lm4;
      M<>N by A8,A17,A28,A49,A53,A60,A63,A61,AFF_1:18;
      then d,q // z,q9 by A1,A3,A5,A6,A7,A9,A24,A61,A67,A73,A57,A70,Lm4;
      hence thesis by A3,A5,A6,A8,A10,A61,A62,A67,A68,A72,A64,A69,Lm4;
    end;
    hence thesis by A32;
  end;
  hence thesis by A1,A3,A5,A8,A10,AFF_1:39;
end;
