reserve a for Real;
reserve p,q for Point of TOP-REAL 2;

theorem Th7:
  for X being non empty TopSpace, f1 being Function of X,R^1 st f1
is continuous holds ex g being Function of X,R^1 st (for p being Point of X,r1
  being Real st f1.p=r1 holds g.p=|.r1.|) & g is continuous
proof
  let X be non empty TopSpace, f1 be Function of X,R^1;
  assume f1 is continuous;
  then consider g1 being Function of X,R^1 such that
A1: for p being Point of X,r1 being Real st f1.p=r1 holds g1.p=r1 ^2 and
A2: g1 is continuous by Th6;
  for q being Point of X ex r being Real st g1.q=r & r>=0
  proof
    let q be Point of X;
    reconsider r11=f1.q as Real;
    g1.q=r11^2 by A1;
    hence thesis by XREAL_1:63;
  end;
  then consider g2 being Function of X,R^1 such that
A3: for p being Point of X,r1 being Real st g1.p=r1 holds g2.p=
  sqrt( r1) and
A4: g2 is continuous by A2,JGRAPH_3:5;
  for p being Point of X,r1 being Real st f1.p=r1 holds g2.p=|.r1.|
  proof
    let p be Point of X,r1 be Real;
    assume f1.p=r1;
    then g1.p=r1^2 by A1;
    then g2.p=sqrt(r1^2) by A3
      .=|.r1.| by COMPLEX1:72;
    hence thesis;
  end;
  hence thesis by A4;
end;
