
theorem Th7:
  for X being TopStruct,S,V being non empty TopStruct, B being non
  empty Subset of S,f being Function of X,S|B, g being Function of S,V, h being
  Function of X,V st h=g*f & f is continuous & g is continuous holds h is
  continuous
proof
  let X be TopStruct,S,V be non empty TopStruct, B be non empty Subset of S, f
  be Function of X,S|B, g be Function of S,V, h being Function of X,V;
  assume that
A1: h=g*f and
A2: f is continuous and
A3: g is continuous;
  now
    let P be Subset of V;
A4: (g*f)"P = f"(g"P) by RELAT_1:146;
    now
      assume P is closed;
      then
A5:   g"P is closed by A3,PRE_TOPC:def 6;
A6:   the carrier of S|B =B by PRE_TOPC:8;
      then reconsider F=B /\ g"P as Subset of S|B by XBOOLE_1:17;
A7:   rng f /\ (the carrier of S|B)= rng f by XBOOLE_1:28;
      [#](S|B)=B by PRE_TOPC:def 5;
      then
A8:   F is closed by A5,PRE_TOPC:13;
      h"P=f"(rng f /\ g"P) by A1,A4,RELAT_1:133
        .=f"(rng f /\ ((the carrier of S|B) /\ g"P)) by A7,XBOOLE_1:16
        .=f"F by A6,RELAT_1:133;
      hence h"P is closed by A2,A8,PRE_TOPC:def 6;
    end;
    hence P is closed implies h"P is closed;
  end;
  hence thesis by PRE_TOPC:def 6;
end;
