reserve i, j, k, n for Nat,
  P for Subset of TOP-REAL 2,
  C for connected compact non vertical non horizontal Subset of TOP-REAL 2;

theorem Th7:
  i < j implies N-bound L~Cage(C,j) < N-bound L~Cage(C,i)
proof
  assume
A1: i < j;
  defpred P[Nat] means i < $1 implies N-bound L~Cage(C,$1) <
  N-bound L~Cage(C,i);
A2: for n being Nat st P[n] holds P[n+1]
  proof
    let n be Nat;
    assume
A3: P[n];
    set j = n + 1, a = N-bound C, s = S-bound C;
A4: a+(a-s)/(2|^j) - (a+(a-s)/(2|^n)) = 0 + (a-s)/(2|^j) - (a-s)/(2|^n)
      .= (a-s)/(2|^n*2) - (a-s)/(2|^n)/(2/2) by NEWTON:6
      .= (a-s)/(2|^n*2) - (a-s)*2/(2|^n*2) by XCMPLX_1:84
      .= (a-s - (2*a-2*s))/(2|^n*2) by XCMPLX_1:120
      .= (s-a)/(2|^n*2);
    2|^n > 0 by NEWTON:83;
    then
A5: 2|^n*2 > 0 * 2 by XREAL_1:68;
A6: N-bound L~Cage(C,n) = a+(a-s)/(2|^n) & N-bound L~Cage(C,j) = a+(a-s)/(
    2|^j) by Th6;
    s - a < 0 by SPRECT_1:32,XREAL_1:49;
    then 0 > a+(a-s)/(2|^j) - (a+(a-s)/(2|^n)) by A5,A4,XREAL_1:141;
    then
A7: N-bound L~Cage(C,n+1) < N-bound L~Cage(C,n) by A6,XREAL_1:48;
    assume i < n+1;
    then i <= n by NAT_1:13;
    hence thesis by A3,A7,XXREAL_0:1,2;
  end;
A8: P[0];
  for n being Nat holds P[n] from NAT_1:sch 2(A8,A2);
  hence thesis by A1;
end;
