reserve i,j,k,n for Nat,
  X,Y,a,b,c,x for set,
  r,s for Real;

theorem Th7:
  for f1,f2,g1,g2 be FinSequence of TOP-REAL 2 st f1^'f2,g1^'g2
  are_in_general_position holds f1^'f2,g1 are_in_general_position
proof
  let f1,f2,g1,g2 be FinSequence of TOP-REAL 2 such that
A1: f1^'f2,g1^'g2 are_in_general_position;
A2: g1^'g2 is_in_general_position_wrt f1^'f2 by A1;
A3: now
    let i;
    assume 1<=i & i < len (f1^'f2);
    then
A4: L~(g1^'g2) /\ LSeg(f1^'f2,i) is trivial by A2;
    L~g1 /\ LSeg(f1^'f2,i) c= L~(g1^'g2) /\ LSeg(f1^'f2,i) by Th5,XBOOLE_1:26;
    hence L~g1 /\ LSeg(f1^'f2,i) is trivial by A4;
  end;
A5: f1^'f2 is_in_general_position_wrt g1^'g2 by A1;
A6: now
    let i such that
A7: 1<=i and
A8: i < len g1;
    len g1 <= len (g1^'g2) by TOPREAL8:7;
    then i < len (g1^'g2) by A8,XXREAL_0:2;
    then L~(f1^'f2) /\ LSeg(g1^'g2,i) is trivial by A5,A7;
    hence L~(f1^'f2) /\ LSeg(g1,i) is trivial by A8,TOPREAL8:28;
  end;
  L~(g1^'g2) misses rng (f1^'f2) by A2;
  then L~g1 misses rng (f1^'f2) by Th5,XBOOLE_1:63;
  then
A9: g1 is_in_general_position_wrt f1^' f2 by A3;
  L~(f1^'f2) misses rng (g1^'g2) by A5;
  then L~(f1^'f2) misses rng g1 by TOPREAL8:10,XBOOLE_1:63;
  then f1^'f2 is_in_general_position_wrt g1 by A6;
  hence thesis by A9;
end;
