 reserve a,b,r for Complex;
 reserve V for ComplexLinearSpace;
reserve A,B for non empty set;
reserve f,g,h for Element of PFuncs(A,COMPLEX);

theorem Th7:
  h = (multcomplexcpfunc A).(a,f) iff dom h = dom f & for x being
  Element of A st x in dom f holds h.x = a * f.x
proof
  hereby
    assume
A1: h = (multcomplexcpfunc A).(a,f);
    then dom h = dom(a(#)f) by Def4;
    hence dom h = dom f by VALUED_1:def 5;
    let x be Element of A;
    assume x in dom f;
    then x in dom(a(#)f) by VALUED_1:def 5;
    then (a(#)f).x = a*(f.x) by VALUED_1:def 5;
    hence h.x = a*(f.x) by A1,Def4;
  end;
  hereby
    reconsider a1=a as Element of COMPLEX by XCMPLX_0:def 2;
    reconsider k= (multcomplexcpfunc A).(a1,f) as Element of PFuncs(A,COMPLEX);
    assume that
A2: dom f = dom h and
A3: for x being Element of A st x in dom f holds h.x = a*f.x;
A4: now
      let x be Element of A;
      assume
A5:   x in dom f;
      then x in dom(a(#)f) by VALUED_1:def 5;
      then (a(#)f).x = a * f.x by VALUED_1:def 5;
      then (a(#)f).x = h.x by A3,A5;
      hence k.x = h.x by Def4;
    end;
    k = a(#)f by Def4;
    then dom k = dom f by VALUED_1:def 5;
    hence h = (multcomplexcpfunc A).(a,f) by A2,A4,PARTFUN1:5;
  end;
end;
