reserve A,B,p,q,r,s for Element of LTLB_WFF,
  n for Element of NAT,
  X for Subset of LTLB_WFF,
  g for Function of LTLB_WFF,BOOLEAN,
  x,y for set;

theorem Th7: p => q in tau1.r implies p in tau1.r & q in tau1.r
  proof
    defpred P1[Element of l] means
    p => q in tau1.$1 implies p in tau1.$1 & q in tau1.$1;
A1: for n holds P1[ prop n]
    proof
      let n;
      set pr = prop n;
      assume p => q in tau1.pr;
      then p => q in {pr} by Def4;
      then p => q = pr by TARSKI:def 1;
      hence p in tau1.pr & q in tau1.pr by HILBERT2:26;
    end;
A2: for r, s st P1[r] & P1[s] holds P1[r 'U' s] & P1[r => s]
    proof
      let r,s;
      assume that
A3:   P1[r] and
A4:   P1[s];
      thus P1[r 'U' s]
      proof
        set f = r 'U' s;
        assume
        p => q in tau1.f;
        then p => q in {f} by Def4;
        then p => q = f by TARSKI:def 1;
        hence p in tau1.f & q in tau1.f by HILBERT2:22;
      end;
      thus P1[r => s]
      proof
        set f = r => s;
A5:     tau1.f = {f} \/ tau1.r \/ tau1.s by Def4;
        then A6: tau1.s c= tau1.f by XBOOLE_1:7;
        tau1.r c= {f} \/ tau1.r & {f} \/ tau1.r c= tau1.f by XBOOLE_1:7,A5;
        then A7: tau1.r c= tau1.f;
        assume
A8:     p => q in tau1.f;
        per cases by A8,A5,XBOOLE_0:def 3;
        suppose
A9:       p => q in {f} \/ tau1.r;
          per cases by A9,XBOOLE_0:def 3;
          suppose p => q in {f};
            then A10: p => q = f by TARSKI:def 1;
            then A11: p = r by HILBERT2:20;
            r in tau1.r by Th6;
            hence p in tau1.f by A11,A7;
A12:        q = s by A10,HILBERT2:20;
            s in tau1.s by Th6;
            hence q in tau1.f by A12,A6;
          end;
          suppose p => q in tau1.r;
            hence p in tau1.f & q in tau1.f by A3,A7;
          end;
        end;
        suppose p => q in tau1.s;
          hence p in tau1.f & q in tau1.f by A4,A6;
        end;
      end;
    end;
A13: P1[TFALSUM]
     proof
       set f = TFALSUM;
       assume p => q in tau1.f;
       then p => q in {f} by Def4;
       then p => q = f by TARSKI:def 1;
       hence p in tau1.f & q in tau1.f by HILBERT2:25;
     end;
     for p holds P1[p] from HILBERT2:sch 2(A13,A1,A2);
     hence thesis;
   end;
