reserve A,B,a,b,c,d,e,f,g,h for set;

theorem
  for R,S be irreflexive RelStr st the carrier of R misses the carrier
  of S holds sum_of(R,S) is irreflexive
proof
  let R,S be irreflexive RelStr such that
A1: the carrier of R misses the carrier of S;
  for x be set st x in the carrier of sum_of(R,S) holds not [x,x] in the
  InternalRel of sum_of(R,S)
  proof
    set IR = the InternalRel of R, IS = the InternalRel of S, RS = [:the
carrier of R,the carrier of S:], SR = [:the carrier of S,the carrier of R:];
    let x be set;
    assume x in the carrier of sum_of(R,S);
    assume not thesis;
    then [x,x] in IR \/ IS \/ RS \/ SR by NECKLA_2:def 3;
    then [x,x] in IR \/ IS \/ RS or [x,x] in SR by XBOOLE_0:def 3;
    then
A2: [x,x] in IR \/ IS or [x,x] in RS or [x,x] in SR by XBOOLE_0:def 3;
    per cases by A2,XBOOLE_0:def 3;
    suppose
A3:   [x,x] in IR;
      then x in the carrier of R by ZFMISC_1:87;
      hence thesis by A3,NECKLACE:def 5;
    end;
    suppose
A4:   [x,x] in IS;
      then x in the carrier of S by ZFMISC_1:87;
      hence thesis by A4,NECKLACE:def 5;
    end;
    suppose
      [x,x] in RS;
      then x in the carrier of R & x in the carrier of S by ZFMISC_1:87;
      hence thesis by A1,XBOOLE_0:3;
    end;
    suppose
      [x,x] in SR;
      then x in the carrier of S & x in the carrier of R by ZFMISC_1:87;
      hence thesis by A1,XBOOLE_0:3;
    end;
  end;
  hence thesis;
end;
